Elliptic curves over number fields

An elliptic curve \(E\) over a number field \(K\) can be given by a Weierstrass equation whose coefficients lie in \(K\) or by using base_extend on an elliptic curve defined over a subfield.

One major difference to elliptic curves over \(\QQ\) is that there might not exist a global minimal equation over \(K\), when \(K\) does not have class number one. Another difference is the lack of understanding of modularity for general elliptic curves over general number fields.

Currently Sage can obtain local information about \(E/K_v\) for finite places \(v\), it has an interface to Denis Simon’s script for 2-descent, it can compute the torsion subgroup of the Mordell-Weil group \(E(K)\), and it can work with isogenies defined over \(K\).

EXAMPLES:

sage: K.<i> = NumberField(x^2+1)
sage: E = EllipticCurve([0,4+i])
sage: E.discriminant()
-3456*i - 6480
sage: P= E([i,2])
sage: P+P
(-2*i + 9/16 : -9/4*i - 101/64 : 1)
sage: E.has_good_reduction(2+i)
True
sage: E.local_data(4+i)
Local data at Fractional ideal (i + 4):
Reduction type: bad additive
Local minimal model: Elliptic Curve defined by y^2 = x^3 + (i+4) over Number Field in i with defining polynomial x^2 + 1
Minimal discriminant valuation: 2
Conductor exponent: 2
Kodaira Symbol: II
Tamagawa Number: 1
sage: E.tamagawa_product_bsd()
1
sage: E.simon_two_descent()
(1, 1, [(i : 2 : 1)])
sage: E.torsion_order()
1
sage: E.isogenies_prime_degree(3)
[Isogeny of degree 3 from Elliptic Curve defined by y^2 = x^3 + (i+4) over Number Field in i with defining polynomial x^2 + 1 to Elliptic Curve defined by y^2 = x^3 + (-27*i-108) over Number Field in i with defining polynomial x^2 + 1]

AUTHORS:

  • Robert Bradshaw 2007
  • John Cremona
  • Chris Wuthrich

REFERENCE:

  • [Sil] Silverman, Joseph H. The arithmetic of elliptic curves. Second edition. Graduate Texts in Mathematics, 106. Springer, 2009.
  • [Sil2] Silverman, Joseph H. Advanced topics in the arithmetic of elliptic curves. Graduate Texts in Mathematics, 151. Springer, 1994.
class sage.schemes.elliptic_curves.ell_number_field.EllipticCurve_number_field(K, ainvs)

Bases: sage.schemes.elliptic_curves.ell_field.EllipticCurve_field

Elliptic curve over a number field.

EXAMPLES:

sage: K.<i> = NumberField(x^2+1)
sage: EllipticCurve([i, i - 1, i + 1, 24*i + 15, 14*i + 35])
Elliptic Curve defined by y^2 + i*x*y + (i+1)*y = x^3 + (i-1)*x^2 + (24*i+15)*x + (14*i+35) over Number Field in i with defining polynomial x^2 + 1
base_extend(R)

Return the base extension of self to \(R\).

EXAMPLES:

sage: E = EllipticCurve('11a3')
sage: K = QuadraticField(-5, 'a')
sage: E.base_extend(K)
Elliptic Curve defined by y^2 + y = x^3 + (-1)*x^2 over Number Field in a with defining polynomial x^2 + 5

Check that non-torsion points are remembered when extending the base field (see trac ticket #16034):

sage: E = EllipticCurve([1, 0, 1, -1751, -31352])
sage: K.<d> = QuadraticField(5)
sage: E.gens()
[(52 : 111 : 1)]
sage: EK = E.base_extend(K)
sage: EK.gens()
[(52 : 111 : 1)]
cm_discriminant()

Return the CM discriminant of the \(j\)-invariant of this curve, or 0.

OUTPUT:

An integer \(D\) which is either \(0\) if this curve \(E\) does not have Complex Multiplication) (CM), or an imaginary quadratic discriminant if \(j(E)\) is the \(j\)-invariant of the order with discriminant \(D\).

Note

If \(E\) has CM but the discriminant \(D\) is not a square in the base field \(K\) then the extra endomorphisms will not be defined over \(K\). See also has_rational_cm().

EXAMPLES:

sage: EllipticCurve(j=0).cm_discriminant()
-3
sage: EllipticCurve(j=1).cm_discriminant()
Traceback (most recent call last):
...
ValueError: Elliptic Curve defined by y^2 + x*y = x^3 + 36*x + 3455 over Rational Field does not have CM
sage: EllipticCurve(j=1728).cm_discriminant()
-4
sage: EllipticCurve(j=8000).cm_discriminant()
-8
sage: K.<a> = QuadraticField(5)
sage: EllipticCurve(j=282880*a + 632000).cm_discriminant()
-20
sage: K.<a> = NumberField(x^3 - 2)
sage: EllipticCurve(j=31710790944000*a^2 + 39953093016000*a + 50337742902000).cm_discriminant()
-108
conductor()

Return the conductor of this elliptic curve as a fractional ideal of the base field.

OUTPUT:

(fractional ideal) The conductor of the curve.

EXAMPLES:

sage: K.<i> = NumberField(x^2+1)
sage: EllipticCurve([i, i - 1, i + 1, 24*i + 15, 14*i + 35]).conductor()
Fractional ideal (21*i - 3)
sage: K.<a> = NumberField(x^2-x+3)
sage: EllipticCurve([1 + a , -1 + a , 1 + a , -11 + a , 5 -9*a  ]).conductor()
Fractional ideal (-6*a)

A not so well known curve with everywhere good reduction:

sage: K.<a> = NumberField(x^2-38)
sage: E = EllipticCurve([0,0,0, 21796814856932765568243810*a - 134364590724198567128296995, 121774567239345229314269094644186997594*a - 750668847495706904791115375024037711300])
sage: E.conductor()
Fractional ideal (1)

An example which used to fail (see trac ticket #5307):

sage: K.<w> = NumberField(x^2+x+6)
sage: E = EllipticCurve([w,-1,0,-w-6,0])
sage: E.conductor()
Fractional ideal (86304, w + 5898)

An example raised in trac ticket #11346:

sage: K.<g> = NumberField(x^2 - x - 1)
sage: E1 = EllipticCurve(K,[0,0,0,-1/48,-161/864])
sage: [(p.smallest_integer(),e) for p,e in E1.conductor().factor()]
[(2, 4), (3, 1), (5, 1)]
division_field(p, names, map=False, **kwds)

Given an elliptic curve over a number field \(F\) and a prime number \(p\), construct the field \(F(E[p])\).

INPUT:

  • p – a prime number (an element of \(\ZZ\))
  • names – a variable name for the number field
  • map – (default: False) also return an embedding of the base_field() into the resulting field.
  • kwds – additional keywords passed to sage.rings.number_field.splitting_field.splitting_field().

OUTPUT:

If map is False, the division field as an absolute number field. If map is True, a tuple (K, phi) where phi is an embedding of the base field in the division field K.

Warning

This takes a very long time when the degree of the division field is large (e.g. when \(p\) is large or when the Galois representation is surjective). The simplify flag also has a big influence on the running time: sometimes simplify=False is faster, sometimes simplify=True (the default) is faster.

EXAMPLES:

The 2-division field is the same as the splitting field of the 2-division polynomial (therefore, it has degree 1, 2, 3 or 6):

sage: E = EllipticCurve('15a1')
sage: K.<b> = E.division_field(2); K
Number Field in b with defining polynomial x
sage: E = EllipticCurve('14a1')
sage: K.<b> = E.division_field(2); K
Number Field in b with defining polynomial x^2 + 5*x + 92
sage: E = EllipticCurve('196b1')
sage: K.<b> = E.division_field(2); K
Number Field in b with defining polynomial x^3 + x^2 - 114*x - 127
sage: E = EllipticCurve('19a1')
sage: K.<b> = E.division_field(2); K
Number Field in b with defining polynomial x^6 + 10*x^5 + 24*x^4 - 212*x^3 + 1364*x^2 + 24072*x + 104292

For odd primes \(p\), the division field is either the splitting field of the \(p\)-division polynomial, or a quadratic extension of it.

sage: E = EllipticCurve('50a1')
sage: F.<a> = E.division_polynomial(3).splitting_field(simplify_all=True); F
Number Field in a with defining polynomial x^6 - 3*x^5 + 4*x^4 - 3*x^3 - 2*x^2 + 3*x + 3
sage: K.<b> = E.division_field(3, simplify_all=True); K
Number Field in b with defining polynomial x^6 - 3*x^5 + 4*x^4 - 3*x^3 - 2*x^2 + 3*x + 3

If we take any quadratic twist, the splitting field of the 3-division polynomial remains the same, but the 3-division field becomes a quadratic extension:

sage: E = E.quadratic_twist(5)  # 50b3
sage: F.<a> = E.division_polynomial(3).splitting_field(simplify_all=True); F
Number Field in a with defining polynomial x^6 - 3*x^5 + 4*x^4 - 3*x^3 - 2*x^2 + 3*x + 3
sage: K.<b> = E.division_field(3, simplify_all=True); K
Number Field in b with defining polynomial x^12 - 3*x^11 + 8*x^10 - 15*x^9 + 30*x^8 - 63*x^7 + 109*x^6 - 144*x^5 + 150*x^4 - 120*x^3 + 68*x^2 - 24*x + 4

Try another quadratic twist, this time over a subfield of \(F\):

sage: G.<c>,_,_ = F.subfields(3)[0]
sage: E = E.base_extend(G).quadratic_twist(c); E
Elliptic Curve defined by y^2 = x^3 + 5*a0*x^2 + (-200*a0^2)*x + (-42000*a0^2+42000*a0+126000) over Number Field in a0 with defining polynomial x^3 - 3*x^2 + 3*x + 9
sage: K.<b> = E.division_field(3, simplify_all=True); K
Number Field in b with defining polynomial x^12 - 10*x^10 + 55*x^8 - 60*x^6 + 75*x^4 + 1350*x^2 + 2025

Some higher-degree examples:

sage: E = EllipticCurve('11a1')
sage: K.<b> = E.division_field(2); K
Number Field in b with defining polynomial x^6 + 2*x^5 - 48*x^4 - 436*x^3 + 1668*x^2 + 28792*x + 73844
sage: K.<b> = E.division_field(3); K  # long time (3s on sage.math, 2014)
Number Field in b with defining polynomial x^48 ...
sage: K.<b> = E.division_field(5); K
Number Field in b with defining polynomial x^4 - x^3 + x^2 - x + 1
sage: E.division_field(5, 'b', simplify=False)
Number Field in b with defining polynomial x^4 + x^3 + 11*x^2 + 41*x + 101
sage: E.base_extend(K).torsion_subgroup()  # long time (2s on sage.math, 2014)
Torsion Subgroup isomorphic to Z/5 + Z/5 associated to the Elliptic Curve defined by y^2 + y = x^3 + (-1)*x^2 + (-10)*x + (-20) over Number Field in b with defining polynomial x^4 - x^3 + x^2 - x + 1

sage: E = EllipticCurve('27a1')
sage: K.<b> = E.division_field(3); K
Number Field in b with defining polynomial x^2 + 3*x + 9
sage: K.<b> = E.division_field(2); K
Number Field in b with defining polynomial x^6 + 6*x^5 + 24*x^4 - 52*x^3 - 228*x^2 + 744*x + 3844
sage: K.<b> = E.division_field(2, simplify_all=True); K
Number Field in b with defining polynomial x^6 - 3*x^5 + 5*x^3 - 3*x + 1
sage: K.<b> = E.division_field(5); K   # long time (4s on sage.math, 2014)
Number Field in b with defining polynomial x^48 ...
sage: K.<b> = E.division_field(7); K  # long time (8s on sage.math, 2014)
Number Field in b with defining polynomial x^72 ...

Over a number field:

sage: R.<x> = PolynomialRing(QQ)
sage: K.<i> = NumberField(x^2 + 1)
sage: E = EllipticCurve([0,0,0,0,i])
sage: L.<b> = E.division_field(2); L
Number Field in b with defining polynomial x^4 - x^2 + 1
sage: L.<b>, phi = E.division_field(2, map=True); phi
Ring morphism:
  From: Number Field in i with defining polynomial x^2 + 1
  To:   Number Field in b with defining polynomial x^4 - x^2 + 1
  Defn: i |--> -b^3
sage: L.<b>, phi = E.division_field(3, map=True)
sage: L
Number Field in b with defining polynomial x^24 - 6*x^22 - 12*x^21 - 21*x^20 + 216*x^19 + 48*x^18 + 804*x^17 + 1194*x^16 - 13488*x^15 + 21222*x^14 + 44196*x^13 - 47977*x^12 - 102888*x^11 + 173424*x^10 - 172308*x^9 + 302046*x^8 + 252864*x^7 - 931182*x^6 + 180300*x^5 + 879567*x^4 - 415896*x^3 + 1941012*x^2 + 650220*x + 443089
sage: phi
Ring morphism:
  From: Number Field in i with defining polynomial x^2 + 1
  To:   Number Field in b with defining polynomial x^24 ...
  Defn: i |--> -215621657062634529/183360797284413355040732*b^23 ...

AUTHORS:

  • Jeroen Demeyer (2014-01-06): trac ticket #11905, use splitting_field method, moved from gal_reps.py, make it work over number fields.
galois_representation()

The compatible family of the Galois representation attached to this elliptic curve.

Given an elliptic curve \(E\) over a number field \(K\) and a rational prime number \(p\), the \(p^n\)-torsion \(E[p^n]\) points of \(E\) is a representation of the absolute Galois group of \(K\). As \(n\) varies we obtain the Tate module \(T_p E\) which is a a representation of \(G_K\) on a free \(\ZZ_p\)-module of rank \(2\). As \(p\) varies the representations are compatible.

EXAMPLES:

sage: K = NumberField(x**2 + 1, 'a')
sage: E = EllipticCurve('11a1').change_ring(K)
sage: rho = E.galois_representation()
sage: rho
Compatible family of Galois representations associated to the Elliptic Curve defined by y^2 + y = x^3 + (-1)*x^2 + (-10)*x + (-20) over Number Field in a with defining polynomial x^2 + 1
sage: rho.is_surjective(3)
True
sage: rho.is_surjective(5)  # long time (4s on sage.math, 2014)
False
sage: rho.non_surjective()
[5]
gens(**kwds)

Return some points of infinite order on this elliptic curve.

Contrary to what the name of this method suggests, the points it returns do not always generate a subgroup of full rank in the Mordell-Weil group, nor are they necessarily linearly independent. Moreover, the number of points can be smaller or larger than what one could expect after calling rank() or rank_bounds().

Note

The optional parameters control the Simon two descent algorithm; see the documentation of simon_two_descent() for more details.

INPUT:

  • verbose – 0, 1, 2, or 3 (default: 0), the verbosity level
  • lim1 – (default: 2) limit on trivial points on quartics
  • lim3 – (default: 4) limit on points on ELS quartics
  • limtriv – (default: 2) limit on trivial points on elliptic curve
  • maxprob – (default: 20)
  • limbigprime – (default: 30) to distinguish between small and large prime numbers. Use probabilistic tests for large primes. If 0, do not use probabilistic tests.
  • known_points – (default: None) list of known points on the curve

OUTPUT:

A set of points of infinite order given by the Simon two-descent.

Note

For non-quadratic number fields, this code does return, but it takes a long time.

EXAMPLES:

sage: K.<a> = NumberField(x^2 + 23, 'a')
sage: E = EllipticCurve(K,[0,0,0,101,0])
sage: E.gens()
[(23831509/8669448*a - 2867471/8669448 : 76507317707/18049790736*a - 424166479633/18049790736 : 1),
 (-2031032029/969232392*a + 58813561/969232392 : -15575984630401/21336681877488*a + 451041199309/21336681877488 : 1),
 (-186948623/4656964 : 549438861195/10049728312*a : 1)]

It can happen that no points are found if the height bounds used in the search are too small (see trac ticket #10745):

sage: K.<y> = NumberField(x^4 + x^2 - 7)
sage: E = EllipticCurve(K, [1, 0, 5*y^2 + 16, 0, 0])
sage: E.gens(lim1=1, lim3=1)
[]
sage: E.rank(), E.gens(lim3=12)  # long time (about 4s)
(1,
 [(369/25*y^3 + 539/25*y^2 + 1178/25*y + 1718/25 : -29038/125*y^3 - 43003/125*y^2 - 92706/125*y - 137286/125 : 1)])

Here is a curve of rank 2:

sage: K.<t> = NumberField(x^2-17)
sage: E = EllipticCurve(K,[-4,0])
sage: E.gens()
[(-1/2*t + 1/2 : -1/2*t + 1/2 : 1), (-t + 3 : -2*t + 10 : 1)]
sage: E.rank()
2

Test that points of finite order are not included (see trac ticket #13593):

sage: E = EllipticCurve("17a3")
sage: K.<t> = NumberField(x^2+3)
sage: EK = E.base_extend(K)
sage: EK.rank()
0
sage: EK.gens()
[]

IMPLEMENTATION:

For curves over quadratic fields which are base-changes from \(\QQ\), we delegate the work to gens_quadratic() where methods over \(\QQ\) suffice. Otherwise, we use Denis Simon’s PARI/GP scripts from http://www.math.unicaen.fr/~simon/.

gens_quadratic(**kwds)

Return generators for the Mordell-Weil group modulo torsion, for a curve which is a base change from \(\QQ\) to a quadratic field.

EXAMPLES:

sage: E = EllipticCurve([1,2,3,40,50])
sage: E.conductor()
2123582
sage: E.gens()
[(5 : 17 : 1)]
sage: K.<i> = QuadraticField(-1)
sage: EK = E.change_ring(K)
sage: EK.gens_quadratic()
[(5 : 17 : 1), (-13 : 48*i + 5 : 1)]

sage: E.change_ring(QuadraticField(3, 'a')).gens_quadratic()
[(5 : 17 : 1), (-1 : 2*a - 1 : 1), (11/4 : 33/4*a - 23/8 : 1)]

sage: K.<a> = QuadraticField(-7)
sage: E = EllipticCurve([0,0,0,197,0])
sage: E.conductor()
2483776
sage: E.gens()
[(47995604297578081/7389879786648100 : -25038161802544048018837479/635266655830129794121000 : 1)]
sage: K.<a> = QuadraticField(7)
sage: E.change_ring(K).gens_quadratic()
[(-1209642055/59583566*a + 1639995844/29791783 : -377240626321899/1720892553212*a + 138577803462855/245841793316 : 1),
 (1/28 : 393/392*a : 1),
 (-61*a + 162 : 1098*a - 2916 : 1)]

sage: E = EllipticCurve([1, a])
sage: E.gens_quadratic()
Traceback (most recent call last):
...
ValueError: gens_quadratic() requires the elliptic curve to be a base change from Q
global_integral_model()

Return a model of self which is integral at all primes.

EXAMPLES:

sage: K.<i> = NumberField(x^2+1)
sage: E = EllipticCurve([i/5,i/5,i/5,i/5,i/5])
sage: P1,P2 = K.primes_above(5)
sage: E.global_integral_model()
Elliptic Curve defined by y^2 + (-i)*x*y + (-25*i)*y = x^3 + 5*i*x^2 + 125*i*x + 3125*i over Number Field in i with defining polynomial x^2 + 1

trac ticket #7935:

sage: K.<a> = NumberField(x^2-38)
sage: E = EllipticCurve([a,1/2])
sage: E.global_integral_model()
Elliptic Curve defined by y^2 = x^3 + 1444*a*x + 27436 over Number Field in a with defining polynomial x^2 - 38

trac ticket #9266:

sage: K.<s> = NumberField(x^2-5)
sage: w = (1+s)/2
sage: E = EllipticCurve(K,[2,w])
sage: E.global_integral_model()
Elliptic Curve defined by y^2 = x^3 + 2*x + (1/2*s+1/2) over Number Field in s with defining polynomial x^2 - 5

trac ticket #12151:

sage: K.<v> = NumberField(x^2 + 161*x - 150)
sage: E = EllipticCurve([25105/216*v - 3839/36, 634768555/7776*v - 98002625/1296, 634768555/7776*v - 98002625/1296, 0, 0])
sage: E.global_integral_model()
Elliptic Curve defined by y^2 + (2094779518028859*v-1940492905300351)*x*y + (477997268472544193101178234454165304071127500*v-442791377441346852919930773849502871958097500)*y = x^3 + (26519784690047674853185542622500*v-24566525306469707225840460652500)*x^2 over Number Field in v with defining polynomial x^2 + 161*x - 150

trac ticket #14476:

sage: R.<t> = QQ[]
sage: K.<g> = NumberField(t^4 - t^3 - 3*t^2 - t + 1)
sage: E = EllipticCurve([ -43/625*g^3 + 14/625*g^2 - 4/625*g + 706/625, -4862/78125*g^3 - 4074/78125*g^2 - 711/78125*g + 10304/78125,  -4862/78125*g^3 - 4074/78125*g^2 - 711/78125*g + 10304/78125, 0,0])
sage: E.global_integral_model()
Elliptic Curve defined by y^2 + (15*g^3-48*g-42)*x*y + (-111510*g^3-162162*g^2-44145*g+37638)*y = x^3 + (-954*g^3-1134*g^2+81*g+576)*x^2 over Number Field in g with defining polynomial t^4 - t^3 - 3*t^2 - t + 1
global_minimal_model(proof=None, semi_global=False)

Return a model of self that is integral, and minimal.

Note

Over fields of class number greater than 1, a global minimal model may not exist. If it does not, set the parameter semi_global to True to obtain a model minimal at all but one prime.

INPUT:

  • proof – whether to only use provably correct methods (default controlled by global proof module). Note that the proof module is number_field, not elliptic_curves, since the functions that actually need the flag are in number fields.
  • semi_global (boolean, default False) – if there is no global minimal mode, return a semi-global minimal model (minimal at all but one prime) instead, if True; raise an error if False. No effect if a global minimal model exists.

OUTPUT:

A global integral and minimal model, or an integral model minimal at all but one prime of there is no global minimal model and the flag semi_global is True.

EXAMPLES:

sage: K.<a> = NumberField(x^2-38)
sage: E = EllipticCurve([0,0,0, 21796814856932765568243810*a - 134364590724198567128296995, 121774567239345229314269094644186997594*a - 750668847495706904791115375024037711300])
sage: E2 = E.global_minimal_model()
sage: E2
Elliptic Curve defined by y^2 + a*x*y + (a+1)*y = x^3 + (a+1)*x^2 + (4*a+15)*x + (4*a+21) over Number Field in a with defining polynomial x^2 - 38
sage: E2.local_data()
[]

See trac ticket #11347:

sage: K.<g> = NumberField(x^2 - x - 1)
sage: E = EllipticCurve(K,[0,0,0,-1/48,161/864]).integral_model().global_minimal_model(); E
Elliptic Curve defined by y^2 + x*y + y = x^3 + x^2 over Number Field in g with defining polynomial x^2 - x - 1
sage: [(p.norm(), e) for p, e in E.conductor().factor()]
[(9, 1), (5, 1)]
sage: [(p.norm(), e) for p, e in E.discriminant().factor()]
[(-5, 2), (9, 1)]

See trac ticket #14472, this used not to work over a relative extension:

sage: K1.<w> = NumberField(x^2+x+1)
sage: m = polygen(K1)
sage: K2.<v> = K1.extension(m^2-w+1)
sage: E = EllipticCurve([0*v,-432])
sage: E.global_minimal_model()
Elliptic Curve defined by y^2 + y = x^3 over Number Field in v with defining polynomial x^2 - w + 1 over its base field

See trac ticket #18662: for fields of class number greater than 1, even when global minimal models did exist, their computation was not implemented. Now it is:

sage: K.<a> = NumberField(x^2-10)
sage: K.class_number()
2
sage: E = EllipticCurve([0,0,0,-186408*a - 589491, 78055704*a + 246833838])
sage: E.discriminant().norm()
16375845905239507992576
sage: E.discriminant().norm().factor()
2^31 * 3^27
sage: E.has_global_minimal_model()
True
sage: Emin = E.global_minimal_model(); Emin
Elliptic Curve defined by y^2 + (a+1)*x*y + (a+1)*y = x^3 + (-a)*x^2 + (a-12)*x + (-2*a+2) over Number Field in a with defining polynomial x^2 - 10
sage: Emin.discriminant().norm()
3456
sage: Emin.discriminant().norm().factor()
2^7 * 3^3

If there is no global minimal model, this method will raise an error unless you set the parameter semi_global to True:

sage: K.<a> = NumberField(x^2-10)
sage: K.class_number()
2
sage: E = EllipticCurve([a,a,0,3*a+8,4*a+3])
sage: E.has_global_minimal_model()
False
sage: E.global_minimal_model()
Traceback (most recent call last):
...
ValueError: Elliptic Curve defined by y^2 + a*x*y = x^3 + a*x^2 + (3*a+8)*x + (4*a+3) over Number Field in a with defining polynomial x^2 - 10 has no global minimal model!  For a semi-global minimal model use semi_global=True
sage: E.global_minimal_model(semi_global=True)
Elliptic Curve defined by y^2 + a*x*y = x^3 + a*x^2 + (3*a+8)*x + (4*a+3) over Number Field in a with defining polynomial x^2 - 10

An example of a curve with everywhere good reduction but which has no model with unit discriminant:

sage: K.<a> = NumberField(x^2-x-16)
sage: K.class_number()
2
sage: E = EllipticCurve([0,0,0,-15221331*a - 53748576, -79617688290*a - 281140318368])
sage: Emin = E.global_minimal_model(semi_global=True)
sage: Emin.ainvs()
(a, a - 1, a, 605*a - 2728, 15887*a - 71972)
sage: Emin.discriminant()
-17*a - 16
sage: Emin.discriminant().norm()
-4096
sage: Emin.minimal_discriminant_ideal()
Fractional ideal (1)
sage: E.conductor()
Fractional ideal (1)
global_minimality_class()

Return the obstruction to this curve having a global minimal model.

OUTPUT:

An ideal class of the base number field, which is trivial if and only if the elliptic curve has a global minimal model, and which can be used to find global and semi-global minimal models.

EXAMPLES:

A curve defined over a field of class number 2 with no global minimal model was a nontrivial minimality class:

sage: K.<a> = NumberField(x^2-10)
sage: K.class_number()
2
sage: E = EllipticCurve([0, 0, 0, -22500, 750000*a])
sage: E.global_minimality_class()
Fractional ideal class (10, 5*a)
sage: E.global_minimality_class().order()
2

Over the same field, a curve defined by a non-minimal model has trivial class, showing that a global minimal model does exist:

sage: K.<a> = NumberField(x^2-10)
sage: E = EllipticCurve([0,0,0,4536*a+14148,-163728*a- 474336])
sage: E.is_global_minimal_model()
False
sage: E.global_minimality_class()
Trivial principal fractional ideal class

Over a field of class number 1 the result is always the trivial class:

sage: K.<a> = NumberField(x^2-5)
sage: E = EllipticCurve([0, 0, 0, K(16), K(64)])
sage: E.global_minimality_class()
Trivial principal fractional ideal class

sage: E = EllipticCurve([0, 0, 0, 16, 64])
sage: E.base_field()
Rational Field
sage: E.global_minimality_class()
1
has_additive_reduction(P)

Return True if this elliptic curve has (bad) additive reduction at the prime \(P\).

INPUT:

  • P – a prime ideal of the base field of self, or a field element generating such an ideal.

OUTPUT:

(bool) True if the curve has additive reduction at \(P\), else False.

EXAMPLES:

sage: E = EllipticCurve('27a1')
sage: [(p,E.has_additive_reduction(p)) for p in prime_range(15)]
[(2, False), (3, True), (5, False), (7, False), (11, False), (13, False)]

sage: K.<a> = NumberField(x^3-2)
sage: P17a, P17b = [P for P,e in K.factor(17)]
sage: E = EllipticCurve([0,0,0,0,2*a+1])
sage: [(p,E.has_additive_reduction(p)) for p in [P17a,P17b]]
[(Fractional ideal (4*a^2 - 2*a + 1), False),
(Fractional ideal (2*a + 1), True)]
has_bad_reduction(P)

Return True if this elliptic curve has bad reduction at the prime \(P\).

INPUT:

  • P – a prime ideal of the base field of self, or a field element generating such an ideal.

OUTPUT:

(bool) True if the curve has bad reduction at \(P\), else False.

Note

This requires determining a local integral minimal model; we do not just check that the discriminant of the current model has valuation zero.

EXAMPLES:

sage: E = EllipticCurve('14a1')
sage: [(p,E.has_bad_reduction(p)) for p in prime_range(15)]
[(2, True), (3, False), (5, False), (7, True), (11, False), (13, False)]

sage: K.<a> = NumberField(x^3-2)
sage: P17a, P17b = [P for P,e in K.factor(17)]
sage: E = EllipticCurve([0,0,0,0,2*a+1])
sage: [(p,E.has_bad_reduction(p)) for p in [P17a,P17b]]
[(Fractional ideal (4*a^2 - 2*a + 1), False),
(Fractional ideal (2*a + 1), True)]
has_cm()

Return whether or not this curve has a CM \(j\)-invariant.

OUTPUT:

True if this curve has CM over the algebraic closure of the base field, otherwise False. See also cm_discriminant() and has_rational_cm().

Note

Even if \(E\) has CM in this sense (that its \(j\)-invariant is a CM \(j\)-invariant), if the associated negative discriminant \(D\) is not a square in the base field \(K\), the extra endomorphisms will not be defined over \(K\). See also the method has_rational_cm() which tests whether \(E\) has extra endomorphisms defined over \(K\) or a given extension of \(K\).

EXAMPLES:

sage: EllipticCurve(j=0).has_cm()
True
sage: EllipticCurve(j=1).has_cm()
False
sage: EllipticCurve(j=1728).has_cm()
True
sage: EllipticCurve(j=8000).has_cm()
True
sage: K.<a> = QuadraticField(5)
sage: EllipticCurve(j=282880*a + 632000).has_cm()
True
sage: K.<a> = NumberField(x^3 - 2)
sage: EllipticCurve(j=31710790944000*a^2 + 39953093016000*a + 50337742902000).has_cm()
True
has_global_minimal_model()

Return whether this elliptic curve has a global minimal model.

OUTPUT:

Boolean, True iff a global minimal model exists, i.e. an integral model which is minimal at every prime.

EXAMPLES:

sage: K.<a> = NumberField(x^2-10)
sage: E = EllipticCurve([0,0,0,4536*a+14148,-163728*a-474336])
sage: E.is_global_minimal_model()
False
sage: E.has_global_minimal_model()
True
has_good_reduction(P)

Return True if this elliptic curve has good reduction at the prime \(P\).

INPUT:

  • P – a prime ideal of the base field of self, or a field element generating such an ideal.

OUTPUT:

(bool) – True if the curve has good reduction at \(P\), else False.

Note

This requires determining a local integral minimal model; we do not just check that the discriminant of the current model has valuation zero.

EXAMPLES:

sage: E = EllipticCurve('14a1')
sage: [(p,E.has_good_reduction(p)) for p in prime_range(15)]
[(2, False), (3, True), (5, True), (7, False), (11, True), (13, True)]

sage: K.<a> = NumberField(x^3-2)
sage: P17a, P17b = [P for P,e in K.factor(17)]
sage: E = EllipticCurve([0,0,0,0,2*a+1])
sage: [(p,E.has_good_reduction(p)) for p in [P17a,P17b]]
[(Fractional ideal (4*a^2 - 2*a + 1), True),
(Fractional ideal (2*a + 1), False)]
has_multiplicative_reduction(P)

Return True if this elliptic curve has (bad) multiplicative reduction at the prime \(P\).

Note

See also has_split_multiplicative_reduction() and has_nonsplit_multiplicative_reduction().

INPUT:

  • P – a prime ideal of the base field of self, or a field
    element generating such an ideal.

OUTPUT:

(bool) True if the curve has multiplicative reduction at \(P\), else False.

EXAMPLES:

sage: E = EllipticCurve('14a1')
sage: [(p,E.has_multiplicative_reduction(p)) for p in prime_range(15)]
[(2, True), (3, False), (5, False), (7, True), (11, False), (13, False)]

sage: K.<a> = NumberField(x^3-2)
sage: P17a, P17b = [P for P,e in K.factor(17)]
sage: E = EllipticCurve([0,0,0,0,2*a+1])
sage: [(p,E.has_multiplicative_reduction(p)) for p in [P17a,P17b]]
[(Fractional ideal (4*a^2 - 2*a + 1), False), (Fractional ideal (2*a + 1), False)]
has_nonsplit_multiplicative_reduction(P)

Return True if this elliptic curve has (bad) non-split multiplicative reduction at the prime \(P\).

INPUT:

  • P – a prime ideal of the base field of self, or a field element generating such an ideal.

OUTPUT:

(bool) True if the curve has non-split multiplicative reduction at \(P\), else False.

EXAMPLES:

sage: E = EllipticCurve('14a1')
sage: [(p,E.has_nonsplit_multiplicative_reduction(p)) for p in prime_range(15)]
[(2, True), (3, False), (5, False), (7, False), (11, False), (13, False)]

sage: K.<a> = NumberField(x^3-2)
sage: P17a, P17b = [P for P,e in K.factor(17)]
sage: E = EllipticCurve([0,0,0,0,2*a+1])
sage: [(p,E.has_nonsplit_multiplicative_reduction(p)) for p in [P17a,P17b]]
[(Fractional ideal (4*a^2 - 2*a + 1), False), (Fractional ideal (2*a + 1), False)]
has_rational_cm(field=None)

Return whether or not this curve has CM defined over its base field or a given extension.

INPUT:

  • field – a field, which should be an extension of the base field of the curve. If field is None (the default), it is taken to be the base field of the curve.

OUTPUT:

True if the ring of endomorphisms of this curve over the given field is larger than \(\ZZ\); otherwise False. See also cm_discriminant() and has_cm().

Note

If \(E\) has CM but the discriminant \(D\) is not a square in the given field \(K\) then the extra endomorphisms will not be defined over \(K\), and this function will return False. See also has_cm(). To obtain the CM discriminant, use cm_discriminant().

EXAMPLES:

sage: E = EllipticCurve(j=0)
sage: E.has_cm()
True
sage: E.has_rational_cm()
False
sage: D = E.cm_discriminant(); D
-3
sage: E.has_rational_cm(QuadraticField(D))
True

sage: E = EllipticCurve(j=1728)
sage: E.has_cm()
True
sage: E.has_rational_cm()
False
sage: D = E.cm_discriminant(); D
-4
sage: E.has_rational_cm(QuadraticField(D))
True

Higher degree examples:

sage: K.<a> = QuadraticField(5)
sage: E = EllipticCurve(j=282880*a + 632000)
sage: E.has_cm()
True
sage: E.has_rational_cm()
False
sage: E.cm_discriminant()
-20
sage: E.has_rational_cm(K.extension(x^2+5,'b'))
True

An error is raised if a field is given which is not an extension of the base field:

sage: E.has_rational_cm(QuadraticField(-20))
Traceback (most recent call last):
...
ValueError: Error in has_rational_cm: Number Field in a with defining polynomial x^2 + 20 is not an extension field of Number Field in a with defining polynomial x^2 - 5

sage: K.<a> = NumberField(x^3 - 2)
sage: E = EllipticCurve(j=31710790944000*a^2 + 39953093016000*a + 50337742902000)
sage: E.has_cm()
True
sage: E.has_rational_cm()
False
sage: D = E.cm_discriminant(); D
-108
sage: E.has_rational_cm(K.extension(x^2+108,'b'))
True
has_split_multiplicative_reduction(P)

Return True if this elliptic curve has (bad) split multiplicative reduction at the prime \(P\).

INPUT:

  • P – a prime ideal of the base field of self, or a field element generating such an ideal.

OUTPUT:

(bool) True if the curve has split multiplicative reduction at \(P\), else False.

EXAMPLES:

sage: E = EllipticCurve('14a1')
sage: [(p,E.has_split_multiplicative_reduction(p)) for p in prime_range(15)]
[(2, False), (3, False), (5, False), (7, True), (11, False), (13, False)]

sage: K.<a> = NumberField(x^3-2)
sage: P17a, P17b = [P for P,e in K.factor(17)]
sage: E = EllipticCurve([0,0,0,0,2*a+1])
sage: [(p,E.has_split_multiplicative_reduction(p)) for p in [P17a,P17b]]
[(Fractional ideal (4*a^2 - 2*a + 1), False), (Fractional ideal (2*a + 1), False)]
height_function()

Return the canonical height function attached to self.

EXAMPLES:

sage: K.<a> = NumberField(x^2 - 5)
sage: E = EllipticCurve(K, '11a3')
sage: E.height_function()
EllipticCurveCanonicalHeight object associated to Elliptic Curve defined by y^2 + y = x^3 + (-1)*x^2 over Number Field in a with defining polynomial x^2 - 5
height_pairing_matrix(points=None, precision=None)

Return the height pairing matrix of the given points.

INPUT:

  • points – either a list of points, which must be on this curve, or (default) None, in which case self.gens() will be used.
  • precision – number of bits of precision of result (default: None, for default RealField precision)

EXAMPLES:

sage: E = EllipticCurve([0, 0, 1, -1, 0])
sage: E.height_pairing_matrix()
[0.0511114082399688]

For rank 0 curves, the result is a valid 0x0 matrix:

sage: EllipticCurve('11a').height_pairing_matrix()
[]
sage: E = EllipticCurve('5077a1')
sage: E.height_pairing_matrix([E.lift_x(x) for x in [-2,-7/4,1]], precision=100)
[  1.3685725053539301120518194471  -1.3095767070865761992624519454 -0.63486715783715592064475542573]
[ -1.3095767070865761992624519454   2.7173593928122930896610589220   1.0998184305667292139777571432]
[-0.63486715783715592064475542573   1.0998184305667292139777571432  0.66820516565192793503314205089]

sage: E = EllipticCurve('389a1')
sage: E = EllipticCurve('389a1')
sage: P,Q = E.point([-1,1,1]),E.point([0,-1,1])
sage: E.height_pairing_matrix([P,Q])
[0.686667083305587 0.268478098806726]
[0.268478098806726 0.327000773651605]

Over a number field:

sage: x = polygen(QQ)
sage: K.<t> = NumberField(x^2+47)
sage: EK = E.base_extend(K)
sage: EK.height_pairing_matrix([EK(P),EK(Q)])
[0.686667083305587 0.268478098806726]
[0.268478098806726 0.327000773651605]
sage: K.<i> = QuadraticField(-1)
sage: E = EllipticCurve([0,0,0,i,i])
sage: P = E(-9+4*i,-18-25*i)
sage: Q = E(i,-i)
sage: E.height_pairing_matrix([P,Q])
[  2.16941934493768 -0.870059380421505]
[-0.870059380421505  0.424585837470709]
sage: E.regulator_of_points([P,Q])
0.164101403936070
integral_model()

Return a model of self which is integral at all primes.

EXAMPLES:

sage: K.<i> = NumberField(x^2+1)
sage: E = EllipticCurve([i/5,i/5,i/5,i/5,i/5])
sage: P1,P2 = K.primes_above(5)
sage: E.global_integral_model()
Elliptic Curve defined by y^2 + (-i)*x*y + (-25*i)*y = x^3 + 5*i*x^2 + 125*i*x + 3125*i over Number Field in i with defining polynomial x^2 + 1

trac ticket #7935:

sage: K.<a> = NumberField(x^2-38)
sage: E = EllipticCurve([a,1/2])
sage: E.global_integral_model()
Elliptic Curve defined by y^2 = x^3 + 1444*a*x + 27436 over Number Field in a with defining polynomial x^2 - 38

trac ticket #9266:

sage: K.<s> = NumberField(x^2-5)
sage: w = (1+s)/2
sage: E = EllipticCurve(K,[2,w])
sage: E.global_integral_model()
Elliptic Curve defined by y^2 = x^3 + 2*x + (1/2*s+1/2) over Number Field in s with defining polynomial x^2 - 5

trac ticket #12151:

sage: K.<v> = NumberField(x^2 + 161*x - 150)
sage: E = EllipticCurve([25105/216*v - 3839/36, 634768555/7776*v - 98002625/1296, 634768555/7776*v - 98002625/1296, 0, 0])
sage: E.global_integral_model()
Elliptic Curve defined by y^2 + (2094779518028859*v-1940492905300351)*x*y + (477997268472544193101178234454165304071127500*v-442791377441346852919930773849502871958097500)*y = x^3 + (26519784690047674853185542622500*v-24566525306469707225840460652500)*x^2 over Number Field in v with defining polynomial x^2 + 161*x - 150

trac ticket #14476:

sage: R.<t> = QQ[]
sage: K.<g> = NumberField(t^4 - t^3 - 3*t^2 - t + 1)
sage: E = EllipticCurve([ -43/625*g^3 + 14/625*g^2 - 4/625*g + 706/625, -4862/78125*g^3 - 4074/78125*g^2 - 711/78125*g + 10304/78125,  -4862/78125*g^3 - 4074/78125*g^2 - 711/78125*g + 10304/78125, 0,0])
sage: E.global_integral_model()
Elliptic Curve defined by y^2 + (15*g^3-48*g-42)*x*y + (-111510*g^3-162162*g^2-44145*g+37638)*y = x^3 + (-954*g^3-1134*g^2+81*g+576)*x^2 over Number Field in g with defining polynomial t^4 - t^3 - 3*t^2 - t + 1
is_global_integral_model()

Return whether self is integral at all primes.

EXAMPLES:

sage: K.<i> = NumberField(x^2+1)
sage: E = EllipticCurve([i/5,i/5,i/5,i/5,i/5])
sage: P1,P2 = K.primes_above(5)
sage: Emin = E.global_integral_model()
sage: Emin.is_global_integral_model()
True
is_global_minimal_model()

Return whether this elliptic curve is a global minimal model.

OUTPUT:

Boolean, False if E is not integral, or if E is non-minimal at some prime, else True.

EXAMPLES:

sage: K.<a> = NumberField(x^2-10)
sage: E = EllipticCurve([0, 0, 0, -22500, 750000*a])
sage: E.is_global_minimal_model()
False
sage: E.non_minimal_primes()
[Fractional ideal (2, a), Fractional ideal (5, a)]

sage: E = EllipticCurve([0,0,0,-3024,46224])
sage: E.is_global_minimal_model()
False
sage: E.non_minimal_primes()
[2, 3]
sage: Emin = E.global_minimal_model()
sage: Emin.is_global_minimal_model()
True

A necessary condition to be a global minimal model is that the model must be globally integral:

sage: E = EllipticCurve([0,0,0,1/2,1/3])
sage: E.is_global_minimal_model()
False
sage: Emin.is_global_minimal_model()
True
sage: Emin.ainvs()
(0, 1, 1, -2, 0)
is_isogenous(other, proof=True, maxnorm=100)

Return whether or not self is isogenous to other.

INPUT:

  • other – another elliptic curve.
  • proof (default True) – If False, the function will return True whenever the two curves have the same conductor and are isogenous modulo \(p\) for all primes \(p\) of norm up to maxnorm. If True, the function returns False when the previous condition does not hold, and if it does hold we compute the complete isogeny class to see if the curves are indeed isogenous.
  • maxnorm (integer, default 100) – The maximum norm of primes \(p\) for which isogeny modulo \(p\) will be checked.

OUTPUT:

(bool) True if there is an isogeny from curve self to curve other.

EXAMPLES:

sage: x = polygen(QQ, 'x')
sage: F = NumberField(x^2 -2, 's'); F
Number Field in s with defining polynomial x^2 - 2
sage: E1 = EllipticCurve(F, [7,8])
sage: E2 = EllipticCurve(F, [0,5,0,1,0])
sage: E3 = EllipticCurve(F, [0,-10,0,21,0])
sage: E1.is_isogenous(E2)
False
sage: E1.is_isogenous(E1)
True
sage: E2.is_isogenous(E2)
True
sage: E2.is_isogenous(E1)
False
sage: E2.is_isogenous(E3)
True
sage: x = polygen(QQ, 'x')
sage: F = NumberField(x^2 -2, 's'); F
Number Field in s with defining polynomial x^2 - 2
sage: E = EllipticCurve('14a1')
sage: EE = EllipticCurve('14a2')
sage: E1 = E.change_ring(F)
sage: E2 = EE.change_ring(F)
sage: E1.is_isogenous(E2)
True
sage: x = polygen(QQ, 'x')
sage: F = NumberField(x^2 -2, 's'); F
Number Field in s with defining polynomial x^2 - 2
sage: k.<a> = NumberField(x^3+7)
sage: E = EllipticCurve(F, [7,8])
sage: EE = EllipticCurve(k, [2, 2])
sage: E.is_isogenous(EE)
Traceback (most recent call last):
...
ValueError: Second argument must be defined over the same number field.

Some examples from Cremona’s 1981 tables:

sage: K.<i> = QuadraticField(-1)
sage: E1 = EllipticCurve([i + 1, 0, 1, -240*i - 400, -2869*i - 2627])
sage: E1.conductor()
Fractional ideal (-4*i - 7)
sage: E2 = EllipticCurve([1+i,0,1,0,0])
sage: E2.conductor()
Fractional ideal (-4*i - 7)
sage: E1.is_isogenous(E2) # slower (~500ms)
True
sage: E1.is_isogenous(E2, proof=False) # faster  (~170ms)
True

In this case E1 and E2 are in fact 9-isogenous, as may be deduced from the following:

sage: E3 = EllipticCurve([i + 1, 0, 1, -5*i - 5, -2*i - 5])
sage: E3.is_isogenous(E1)
True
sage: E3.is_isogenous(E2)
True
sage: E1.isogeny_degree(E2)
9
is_local_integral_model(*P)

Tests if self is integral at the prime ideal \(P\), or at all the primes if \(P\) is a list or tuple.

INPUT:

  • *P – a prime ideal, or a list or tuple of primes.

EXAMPLES:

sage: K.<i> = NumberField(x^2+1)
sage: P1,P2 = K.primes_above(5)
sage: E = EllipticCurve([i/5,i/5,i/5,i/5,i/5])
sage: E.is_local_integral_model(P1,P2)
False
sage: Emin = E.local_integral_model(P1,P2)
sage: Emin.is_local_integral_model(P1,P2)
True
isogenies_prime_degree(l=None, algorithm='Billerey', minimal_models=True)

Return a list of \(\ell\)-isogenies from self, where \(\ell\) is a prime.

INPUT:

  • l – either None or a prime or a list of primes.
  • algorithm (string, default ‘Billerey’) – the algorithm to use to compute the reducible primes when l is None. Ignored for CM curves or if l is provided. Values are ‘Billerey’ (default), ‘Larson’, and ‘heuristic’.
  • minimal_models (bool, default True) – if True, all curves computed will be minimal or semi-minimal models. Over fields of larger degree it can be expensive to compute these so set to False.

OUTPUT:

(list) \(\ell\)-isogenies for the given \(\ell\) or if \(\ell\) is None, all isogenies of prime degree (see below for the CM case).

Note

Over \(\QQ\), the codomains of the isogenies returned are standard minimal models. Over other number fields they are global minimal models if these exist, otherwise models which are minimal at all but one prime.

Note

For curves with rational CM, isogenies of primes degree exist for infinitely many primes \(\ell\), though there are only finitely many isogenous curves up to isomorphism. The list returned only includes one isogeny of prime degree for each codomain.

EXAMPLES:

sage: K.<i> = QuadraticField(-1)
sage: E = EllipticCurve(K, [0,0,0,0,1])
sage: isogs = E.isogenies_prime_degree()
sage: [phi.degree() for phi in isogs]
[2, 3]

sage: pol = PolynomialRing(QQ,'x')([1,-3,5,-5,5,-3,1])
sage: L.<a> = NumberField(pol)
sage: js = hilbert_class_polynomial(-23).roots(L,multiplicities=False); len(js)
3
sage: E = EllipticCurve(j=js[0])
sage: len(E.isogenies_prime_degree())  # long time
3

Set minimal_models to False to avoid computing minimal models of the isogenous curves, since that can be time-consuming since it requires computation of the class group:

sage: proof.number_field(False)
sage: K.<z> = CyclotomicField(53)
sage: E = EllipticCurve(K,[0,6,0,2,0])
sage: E.isogenies_prime_degree(2, minimal_models=False)
[Isogeny of degree 2 from Elliptic Curve defined by y^2 = x^3 + 6*x^2 + 2*x over Cyclotomic Field of order 53 and degree 52 to Elliptic Curve defined by y^2 = x^3 + 6*x^2 + (-8)*x + (-48) over Cyclotomic Field of order 53 and degree 52]
sage: E.isogenies_prime_degree(2, minimal_models=True) # not tested (10s)
[Isogeny of degree 2 from Elliptic Curve defined by y^2 = x^3 + 6*x^2 + 2*x over Cyclotomic Field of order 53 and degree 52 to Elliptic Curve defined by y^2 = x^3 + (-20)*x + (-16) over Cyclotomic Field of order 53 and degree 52]
isogeny_class(reducible_primes=None, algorithm='Billerey', minimal_models=True)

Return the isogeny class of this elliptic curve.

INPUT:

  • reducible_primes (list of ints, or None (default)) – if not None then this should be a list of primes; in computing the isogeny class, only composites isogenies of these degrees will be used.
  • algorithm (string, default ‘Billerey’) – the algorithm to use to compute the reducible primes. Ignored for CM curves or if reducible_primes is provided. Values are ‘Billerey’ (default), ‘Larson’, and ‘heuristic’.
  • minimal_models (bool, default True) – if True, all curves in the class will be minimal or semi-minimal models. Over fields of larger degree it can be expensive to compute these so set to False.

OUTPUT:

An instance of the class sage.schemes.elliptic_curves.isogeny_class.IsogenyClass_EC_NumberField. From this object may be obtained a list of curves in the class, a matrix of the degrees of the isogenies between them, and the isogenies themselves.

Note

If using the algorithm ‘heuristic’ for non-CM curves, the result is not guaranteed to be the complete isogeny class, since only reducible primes up to the default bound in reducible_primes_naive() (currently 1000) are tested. However, no examples of non-CM elliptic curves with reducible primes greater than 100 have yet been computed so the output is likely to be correct.

Note

By default, the curves in the isogeny class will all be minimal models if these exist (for example, when the class number is \(1\)); otherwise they will be minimal at all but one prime. This behaviour can be switched off if desired, for example over fields where the computation of the class group would be too expensive.

EXAMPLES:

sage: K.<i> = QuadraticField(-1)
sage: E = EllipticCurve(K, [0,0,0,0,1])
sage: C = E.isogeny_class(); C
Isogeny class of Elliptic Curve defined by y^2 = x^3 + 1 over Number Field in i with defining polynomial x^2 + 1

The curves in the class (sorted):

sage: [E1.ainvs() for E1 in C]
[(0, 0, 0, 0, -27),
(0, 0, 0, 0, 1),
(i + 1, i, i + 1, -i + 3, 4*i),
(i + 1, i, i + 1, -i + 33, -58*i)]

The matrix of degrees of cyclic isogenies between curves:

sage: C.matrix()
[1 3 6 2]
[3 1 2 6]
[6 2 1 3]
[2 6 3 1]

The array of isogenies themselves is not filled out but only contains those used to construct the class, the other entries containing the integer 0. This will be changed when the class EllipticCurveIsogeny allowed composition. In this case we used \(2\)-isogenies to go from 0 to 2 and from 1 to 3, and \(3\)-isogenies to go from 0 to 1 and from 2 to 3:

sage: isogs = C.isogenies()
sage: [((i,j),isogs[i][j].degree()) for i in range(4) for j in range(4) if isogs[i][j]!=0]
[((0, 1), 3),
((0, 3), 2),
((1, 0), 3),
((1, 2), 2),
((2, 1), 2),
((2, 3), 3),
((3, 0), 2),
((3, 2), 3)]
sage: [((i,j),isogs[i][j].x_rational_map()) for i in range(4) for j in range(4) if isogs[i][j]!=0]
[((0, 1), (1/9*x^3 - 12)/x^2),
 ((0, 3), (-1/2*i*x^2 + i*x - 12*i)/(x - 3)),
 ((1, 0), (x^3 + 4)/x^2),
 ((1, 2), (-1/2*i*x^2 - i*x - 2*i)/(x + 1)),
 ((2, 1), (1/2*i*x^2 - x)/(x + 3/2*i)),
 ((2, 3), (x^3 + 4*i*x^2 - 10*x - 10*i)/(x^2 + 4*i*x - 4)),
 ((3, 0), (1/2*i*x^2 + x + 4*i)/(x - 5/2*i)),
 ((3, 2), (1/9*x^3 - 4/3*i*x^2 - 34/3*x + 226/9*i)/(x^2 - 8*i*x - 16))]

The isogeny class may be visualized by obtaining its graph and plotting it:

sage: G = C.graph()
sage: G.show(edge_labels=True) # long time

sage: K.<i> = QuadraticField(-1)
sage: E = EllipticCurve([1+i, -i, i, 1, 0])
sage: C = E.isogeny_class(); C
Isogeny class of Elliptic Curve defined by y^2 + (i+1)*x*y + i*y = x^3 + (-i)*x^2 + x over Number Field in i with defining polynomial x^2 + 1
sage: len(C)
6
sage: C.matrix()
[ 1  3  9 18  6  2]
[ 3  1  3  6  2  6]
[ 9  3  1  2  6 18]
[18  6  2  1  3  9]
[ 6  2  6  3  1  3]
[ 2  6 18  9  3  1]
sage: [E1.ainvs() for E1 in C]
[(i + 1, i - 1, i, -i - 1, -i + 1),
(i + 1, i - 1, i, 14*i + 4, 7*i + 14),
(i + 1, i - 1, i, 59*i + 99, 372*i - 410),
(i + 1, -i, i, -240*i - 399, 2869*i + 2627),
(i + 1, -i, i, -5*i - 4, 2*i + 5),
(i + 1, -i, i, 1, 0)]

An example with CM by \(\sqrt{-5}\):

sage: pol = PolynomialRing(QQ,'x')([1,0,3,0,1])
sage: K.<c> = NumberField(pol)
sage: j = 1480640+565760*c^2
sage: E = EllipticCurve(j=j)
sage: E.has_cm()
True
sage: E.has_rational_cm()
True
sage: E.cm_discriminant()
-20
sage: C = E.isogeny_class()
sage: len(C)
2
sage: C.matrix()
[1 2]
[2 1]
sage: [E.ainvs() for E in C]
[(0, 0, 0, 83490*c^2 - 147015, -64739840*c^2 - 84465260),
(0, 0, 0, -161535*c^2 + 70785, -62264180*c^3 + 6229080*c)]
sage: C.isogenies()[0][1]
Isogeny of degree 2 from Elliptic Curve defined by y^2 = x^3 + (83490*c^2-147015)*x + (-64739840*c^2-84465260) over Number Field in c with defining polynomial x^4 + 3*x^2 + 1 to Elliptic Curve defined by y^2 = x^3 + (-161535*c^2+70785)*x + (-62264180*c^3+6229080*c) over Number Field in c with defining polynomial x^4 + 3*x^2 + 1

An example with CM by \(\sqrt{-23}\) (class number \(3\)):

sage: pol = PolynomialRing(QQ,'x')([1,-3,5,-5,5,-3,1])
sage: L.<a> = NumberField(pol)
sage: js = hilbert_class_polynomial(-23).roots(L,multiplicities=False); len(js)
3
sage: E = EllipticCurve(j=js[0])
sage: E.has_rational_cm()
True
sage: len(E.isogenies_prime_degree())  # long time
3
sage: C = E.isogeny_class(); len(C)  # long time
6

The reason for the isogeny class having size six while the class number is only \(3\) is that the class also contains three curves with CM by the order of discriminant \(-92=4\cdot(-23)\), which also has class number \(3\). The curves in the class are sorted first by CM discriminant (then lexicographically using a-invariants):

sage: [F.cm_discriminant() for F in C]  # long time
[-23, -23, -23, -92, -92, -92]

\(2\) splits in the order with discriminant \(-23\), into two primes of order \(3\) in the class group, each of which induces a \(2\)-isogeny to a curve with the same endomorphism ring; the third \(2\)-isogeny is to a curve with the smaller endomorphism ring:

sage: [phi.codomain().cm_discriminant() for phi in E.isogenies_prime_degree()]  # long time
[-92, -23, -23]

sage: C.matrix()  # long time
[1 2 2 4 2 4]
[2 1 2 2 4 4]
[2 2 1 4 4 2]
[4 2 4 1 3 3]
[2 4 4 3 1 3]
[4 4 2 3 3 1]

The graph of this isogeny class has a shape which does not occur over \(\QQ\): a triangular prism. Note that for curves without CM, the graph has an edge between two curves if and only if they are connected by an isogeny of prime degree, and this degree is uniquely determined by the two curves, but in the CM case this property does not hold, since for pairs of curves in the class with the same endomorphism ring \(O\), the set of degrees of isogenies between them is the set of integers represented by a primitive integral binary quadratic form of discriminant \(\text{disc}(O)\), and this form represents infinitely many primes. In the matrix we give a small prime represented by the appropriate form. In this example, the matrix is formed by four \(3\times3\) blocks. The isogenies of degree \(2\) indicated by the upper left \(3\times3\) block of the matrix could be replaced by isogenies of any degree represented by the quadratic form \(2x^2+xy+3y^2\) of discriminant \(-23\). Similarly in the lower right block, the entries of \(3\) could be represented by any integers represented by the quadratic form \(3x^2+2xy+8y^2\) of discriminant \(-92\). In the top right block and lower left blocks, by contrast, the prime entries \(2\) are unique determined:

sage: G = C.graph()  # long time
sage: G.adjacency_matrix()  # long time
[0 1 1 0 1 0]
[1 0 1 1 0 0]
[1 1 0 0 0 1]
[0 1 0 0 1 1]
[1 0 0 1 0 1]
[0 0 1 1 1 0]

To display the graph without any edge labels:

sage: G.show()  # not tested

To display the graph with edge labels: by default, for curves with rational CM, the labels are the coefficients of the associated quadratic forms:

sage: G.show(edge_labels=True)  # not tested

For an alternative view, first relabel the edges using only 2 labels to distinguish between isogenies between curves with the same endomorphism ring and isogenies between curves with different endomorphism rings, then use a 3-dimensional plot which can be rotated:

sage: for i,j,l in G.edge_iterator():  # long time
....:     G.set_edge_label(i, j, l.count(','))
sage: G.show3d(color_by_label=True)  # long time

A class number \(6\) example. First we set up the fields: pol defines the same field as pol26 but is simpler:

sage: pol26 = hilbert_class_polynomial(-4*26)
sage: pol = x^6-x^5+2*x^4+x^3-2*x^2-x-1
sage: K.<a> = NumberField(pol)
sage: L.<b> = K.extension(x^2+26)

Only \(2\) of the \(j\)-invariants with discriminant -104 are in \(K\), though all are in \(L\):

sage: len(pol26.roots(K))
2
sage: len(pol26.roots(L))
6

We create an elliptic curve defined over \(K\) with one of the \(j\)-invariants in \(K\):

sage: j1 = pol26.roots(K)[0][0]
sage: E = EllipticCurve(j=j1)
sage: E.has_cm()
True
sage: E.has_rational_cm()
False
sage: E.has_rational_cm(L)
True

Over \(K\) the isogeny class has size \(4\), with \(2\) curves for each of the \(2\) \(K\)-rational \(j\)-invariants:

sage: C = E.isogeny_class(); len(C) # long time (~11s)
4
sage: C.matrix()                    # long time
[ 1 13  2 26]
[13  1 26  2]
[ 2 26  1 13]
[26  2 13  1]
sage: len(Set([EE.j_invariant() for EE in C.curves]))  # long time
2

Over \(L\), the isogeny class grows to size \(6\) (the class number):

sage: EL = E.change_ring(L)
sage: CL = EL.isogeny_class(minimal_models=False); len(CL)
6
sage: Set([EE.j_invariant() for EE in CL.curves]) == Set(pol26.roots(L,multiplicities=False))
True

In each position in the matrix of degrees, we see primes (or \(1\)). In fact the set of degrees of cyclic isogenies from curve \(i\) to curve \(j\) is infinite, and is the set of all integers represented by one of the primitive binary quadratic forms of discriminant \(-104\), from which we have selected a small prime:

sage: CL.matrix() # long time # random (see :trac:`19229`)
[1 2 3 3 5 5]
[2 1 5 5 3 3]
[3 5 1 3 2 5]
[3 5 3 1 5 2]
[5 3 2 5 1 3]
[5 3 5 2 3 1]

To see the array of binary quadratic forms:

sage: CL.qf_matrix()  # long time # random (see :trac:`19229`)
[[[1], [2, 0, 13], [3, -2, 9], [3, -2, 9], [5, -4, 6], [5, -4, 6]],
 [[2, 0, 13], [1], [5, -4, 6], [5, -4, 6], [3, -2, 9], [3, -2, 9]],
 [[3, -2, 9], [5, -4, 6], [1], [3, -2, 9], [2, 0, 13], [5, -4, 6]],
 [[3, -2, 9], [5, -4, 6], [3, -2, 9], [1], [5, -4, 6], [2, 0, 13]],
 [[5, -4, 6], [3, -2, 9], [2, 0, 13], [5, -4, 6], [1], [3, -2, 9]],
 [[5, -4, 6], [3, -2, 9], [5, -4, 6], [2, 0, 13], [3, -2, 9], [1]]]

As in the non-CM case, the isogeny class may be visualized by obtaining its graph and plotting it. Since there are more edges than in the non-CM case, it may be preferable to omit the edge_labels:

sage: G = C.graph()
sage: G.show(edge_labels=False) # long time

It is possible to display a 3-dimensional plot, with colours to represent the different edge labels, in a form which can be rotated!:

sage: G.show3d(color_by_label=True) # long time

Over larger number fields several options make computations tractable. Here we use algorithm ‘heuristic’ which avoids a rigorous computation of the reducible primes, only testing those less than 1000, and setting minimal_models to False avoid having to compute the class group of \(K\). To obtain minimal models set proof.number_field(False); the class group computation takes an additional 10s:

sage: K.<z> = CyclotomicField(53)
sage: E = EllipticCurve(K,[0,6,0,2,0])
sage: C = E.isogeny_class(algorithm='heuristic', minimal_models=False); C # long time (10s)
Isogeny class of Elliptic Curve defined by y^2 = x^3 + 6*x^2 + 2*x over Cyclotomic Field of order 53 and degree 52
sage: C.curves # long time
[Elliptic Curve defined by y^2 = x^3 + 6*x^2 + (-8)*x + (-48) over Cyclotomic Field of order 53 and degree 52,
Elliptic Curve defined by y^2 = x^3 + 6*x^2 + 2*x over Cyclotomic Field of order 53 and degree 52]
isogeny_degree(other)

Return the minimal degree of an isogeny between self and other, or 0 if no isogeny exists.

INPUT:

  • other – another elliptic curve.

OUTPUT:

(int) The degree of an isogeny from self to other, or 0.

EXAMPLES:

sage: x = QQ['x'].0
sage: F = NumberField(x^2 -2, 's'); F
Number Field in s with defining polynomial x^2 - 2
sage: E = EllipticCurve('14a1')
sage: EE = EllipticCurve('14a2')
sage: E1 = E.change_ring(F)
sage: E2 = EE.change_ring(F)
sage: E1.isogeny_degree(E2)  # long time
2
sage: E2.isogeny_degree(E2)
1
sage: E5 = EllipticCurve('14a5').change_ring(F)
sage: E1.isogeny_degree(E5)  # long time
6

sage: E = EllipticCurve('11a1')
sage: [E2.label() for E2 in cremona_curves([11..20]) if E.isogeny_degree(E2)]
['11a1', '11a2', '11a3']

sage: K.<i> = QuadraticField(-1)
sage: E = EllipticCurve([1+i, -i, i, 1, 0])
sage: C = E.isogeny_class()
sage: [E.isogeny_degree(F) for F in C]
[2, 6, 18, 9, 3, 1]
kodaira_symbol(P, proof=None)

Return the Kodaira Symbol of this elliptic curve at the prime \(P\).

INPUT:

  • P – either None or a prime ideal of the base field of self.
  • proof – whether to only use provably correct methods (default controlled by global proof module). Note that the proof module is number_field, not elliptic_curves, since the functions that actually need the flag are in number fields.

OUTPUT:

The Kodaira Symbol of the curve at P, represented as a string.

EXAMPLES:

sage: K.<a> = NumberField(x^2-5)
sage: E = EllipticCurve([20, 225, 750, 625*a + 6875, 31250*a + 46875])
sage: bad_primes = E.discriminant().support(); bad_primes
[Fractional ideal (-a), Fractional ideal (7/2*a - 81/2), Fractional ideal (-a - 52), Fractional ideal (2)]
sage: [E.kodaira_symbol(P) for P in bad_primes]
[I0, I1, I1, II]
sage: K.<a> = QuadraticField(-11)
sage: E = EllipticCurve('11a1').change_ring(K)
sage: [E.kodaira_symbol(P) for P in K(11).support()]
[I10]
lll_reduce(points, height_matrix=None, precision=None)

Return an LLL-reduced basis from a given basis, with transform matrix.

INPUT:

  • points - a list of points on this elliptic curve, which should be independent.
  • height_matrix - the height-pairing matrix of the points, or None. If None, it will be computed.
  • precision - number of bits of precision of intermediate computations (default: None, for default RealField precision; ignored if height_matrix is supplied)

OUTPUT: A tuple (newpoints, U) where U is a unimodular integer matrix, new_points is the transform of points by U, such that new_points has LLL-reduced height pairing matrix

Note

If the input points are not independent, the output depends on the undocumented behaviour of PARI’s qflllgram() function when applied to a gram matrix which is not positive definite.

EXAMPLES:

Some examples over \(\QQ\):

sage: E = EllipticCurve([0, 1, 1, -2, 42])
sage: Pi = E.gens(); Pi
[(-4 : 1 : 1), (-3 : 5 : 1), (-11/4 : 43/8 : 1), (-2 : 6 : 1)]
sage: Qi, U = E.lll_reduce(Pi)
sage: all(sum(U[i,j]*Pi[i] for i in range(4)) == Qi[j] for j in range(4))
True
sage: sorted(Qi)
[(-4 : 1 : 1), (-3 : 5 : 1), (-2 : 6 : 1), (0 : 6 : 1)]
sage: U.det()
1
sage: E.regulator_of_points(Pi)
4.59088036960573
sage: E.regulator_of_points(Qi)
4.59088036960574
sage: E = EllipticCurve([1,0,1,-120039822036992245303534619191166796374,504224992484910670010801799168082726759443756222911415116])
sage: xi = [2005024558054813068,\
-4690836759490453344,\
4700156326649806635,\
6785546256295273860,\
6823803569166584943,\
7788809602110240789,\
27385442304350994620556,\
54284682060285253719/4,\
-94200235260395075139/25,\
-3463661055331841724647/576,\
-6684065934033506970637/676,\
-956077386192640344198/2209,\
-27067471797013364392578/2809,\
-25538866857137199063309/3721,\
-1026325011760259051894331/108241,\
9351361230729481250627334/1366561,\
10100878635879432897339615/1423249,\
11499655868211022625340735/17522596,\
110352253665081002517811734/21353641,\
414280096426033094143668538257/285204544,\
36101712290699828042930087436/4098432361,\
45442463408503524215460183165/5424617104,\
983886013344700707678587482584/141566320009,\
1124614335716851053281176544216033/152487126016]
sage: points = [E.lift_x(x) for x in xi]
sage: newpoints, U = E.lll_reduce(points)  # long time (35s on sage.math, 2011)
sage: [P[0] for P in newpoints]            # long time
[6823803569166584943, 5949539878899294213, 2005024558054813068, 5864879778877955778, 23955263915878682727/4, 5922188321411938518, 5286988283823825378, 175620639884534615751/25, -11451575907286171572, 3502708072571012181, 1500143935183238709184/225, 27180522378120223419/4, -5811874164190604461581/625, 26807786527159569093, 7404442636649562303, 475656155255883588, 265757454726766017891/49, 7272142121019825303, 50628679173833693415/4, 6951643522366348968, 6842515151518070703, 111593750389650846885/16, 2607467890531740394315/9, -1829928525835506297]

An example to show the explicit use of the height pairing matrix:

sage: E = EllipticCurve([0, 1, 1, -2, 42])
sage: Pi = E.gens()
sage: H = E.height_pairing_matrix(Pi,3)
sage: E.lll_reduce(Pi,height_matrix=H)
(
                                                          [1 0 0 1]
                                                          [0 1 0 1]
                                                          [0 0 0 1]
[(-4 : 1 : 1), (-3 : 5 : 1), (-2 : 6 : 1), (1 : -7 : 1)], [0 0 1 1]
)

Some examples over number fields (see trac ticket #9411):

sage: K.<a> = QuadraticField(-23, 'a')
sage: E = EllipticCurve(K, [0,0,1,-1,0])
sage: P = E(-2,-(a+1)/2)
sage: Q = E(0,-1)
sage: E.lll_reduce([P,Q])
(
                                         [0 1]
[(0 : -1 : 1), (-2 : -1/2*a - 1/2 : 1)], [1 0]
)
sage: K.<a> = QuadraticField(-5)
sage: E = EllipticCurve(K,[0,a])
sage: points = [E.point([-211/841*a - 6044/841,-209584/24389*a + 53634/24389]),E.point([-17/18*a - 1/9, -109/108*a - 277/108]) ]
sage: E.lll_reduce(points)
(
[(-a + 4 : -3*a + 7 : 1), (-17/18*a - 1/9 : 109/108*a + 277/108 : 1)],
[ 1  0]
[ 1 -1]
)
local_data(P=None, proof=None, algorithm='pari', globally=False)

Local data for this elliptic curve at the prime \(P\).

INPUT:

  • P – either None, a prime ideal of the base field of self, or an element of the base field that generates a prime ideal.
  • proof – whether to only use provably correct methods (default controlled by global proof module). Note that the proof module is number_field, not elliptic_curves, since the functions that actually need the flag are in number fields.
  • algorithm (string, default: “pari”) – Ignored unless the base field is \(\QQ\). If “pari”, use the PARI C-library ellglobalred implementation of Tate’s algorithm over \(\QQ\). If “generic”, use the general number field implementation.
  • globally – whether the local algorithm uses global generators for the prime ideals. Default is False, which will not require any information about the class group. If True, a generator for \(P\) will be used if \(P\) is principal. Otherwise, or if globally is False, the minimal model returned will preserve integrality at other primes, but not minimality.

OUTPUT:

If \(P\) is specified, returns the EllipticCurveLocalData object associated to the prime \(P\) for this curve. Otherwise, returns a list of such objects, one for each prime \(P\) in the support of the discriminant of this model.

Note

The model is not required to be integral on input.

EXAMPLES:

sage: K.<i> = NumberField(x^2+1)
sage: E = EllipticCurve([1 + i, 0, 1, 0, 0])
sage: E.local_data()
[Local data at Fractional ideal (2*i + 1):
Reduction type: bad non-split multiplicative
Local minimal model: Elliptic Curve defined by y^2 + (i+1)*x*y + y = x^3 over Number Field in i with defining polynomial x^2 + 1
Minimal discriminant valuation: 1
Conductor exponent: 1
Kodaira Symbol: I1
Tamagawa Number: 1,
Local data at Fractional ideal (-3*i - 2):
Reduction type: bad split multiplicative
Local minimal model: Elliptic Curve defined by y^2 + (i+1)*x*y + y = x^3 over Number Field in i with defining polynomial x^2 + 1
Minimal discriminant valuation: 2
Conductor exponent: 1
Kodaira Symbol: I2
Tamagawa Number: 2]
sage: E.local_data(K.ideal(3))
Local data at Fractional ideal (3):
Reduction type: good
Local minimal model: Elliptic Curve defined by y^2 + (i+1)*x*y + y = x^3 over Number Field in i with defining polynomial x^2 + 1
Minimal discriminant valuation: 0
Conductor exponent: 0
Kodaira Symbol: I0
Tamagawa Number: 1
sage: E.local_data(2*i + 1)
Local data at Fractional ideal (2*i + 1):
Reduction type: bad non-split multiplicative
Local minimal model: Elliptic Curve defined by y^2 + (i+1)*x*y + y = x^3 over Number Field in i with defining polynomial x^2 + 1
Minimal discriminant valuation: 1
Conductor exponent: 1
Kodaira Symbol: I1
Tamagawa Number: 1

An example raised in trac ticket #3897:

sage: E = EllipticCurve([1,1])
sage: E.local_data(3)
Local data at Principal ideal (3) of Integer Ring:
Reduction type: good
Local minimal model: Elliptic Curve defined by y^2 = x^3 + x + 1 over Rational Field
Minimal discriminant valuation: 0
Conductor exponent: 0
Kodaira Symbol: I0
Tamagawa Number: 1
local_integral_model(*P)

Return a model of self which is integral at the prime ideal \(P\).

Note

The integrality at other primes is not affected, even if \(P\) is non-principal.

INPUT:

  • *P – a prime ideal, or a list or tuple of primes.

EXAMPLES:

sage: K.<i> = NumberField(x^2+1)
sage: P1,P2 = K.primes_above(5)
sage: E = EllipticCurve([i/5,i/5,i/5,i/5,i/5])
sage: E.local_integral_model((P1,P2))
Elliptic Curve defined by y^2 + (-i)*x*y + (-25*i)*y = x^3 + 5*i*x^2 + 125*i*x + 3125*i over Number Field in i with defining polynomial x^2 + 1
local_minimal_model(P, proof=None, algorithm='pari')

Return a model which is integral at all primes and minimal at \(P\).

INPUT:

  • P – either None or a prime ideal of the base field of self.
  • proof – whether to only use provably correct methods (default controlled by global proof module). Note that the proof module is number_field, not elliptic_curves, since the functions that actually need the flag are in number fields.
  • algorithm (string, default: “pari”) – Ignored unless the base field is \(\QQ\). If “pari”, use the PARI C-library ellglobalred implementation of Tate’s algorithm over \(\QQ\). If “generic”, use the general number field implementation.

OUTPUT:

A model of the curve which is minimal (and integral) at \(P\).

Note

The model is not required to be integral on input.

For principal \(P\), a generator is used as a uniformizer, and integrality or minimality at other primes is not affected. For non-principal \(P\), the minimal model returned will preserve integrality at other primes, but not minimality.

EXAMPLES:

sage: K.<a> = NumberField(x^2-5)
sage: E = EllipticCurve([20, 225, 750, 1250*a + 6250, 62500*a + 15625])
sage: P = K.ideal(a)
sage: E.local_minimal_model(P).ainvs()
(0, 1, 0, 2*a - 34, -4*a + 66)
minimal_discriminant_ideal()

Return the minimal discriminant ideal of this elliptic curve.

OUTPUT:

The integral ideal \(D\) whose valuation at every prime \(P\) is that of the local minimal model for \(E\) at \(P\). If \(E\) has a global minimal model, this will be the principal ideal generated by the discriminant of any such model, but otherwise it can be a proper divisor of the discriminant of any model.

EXAMPLES:

sage: K.<a> = NumberField(x^2-x-57)
sage: K.class_number()
3
sage: E = EllipticCurve([a,-a,a,-5692-820*a,-259213-36720*a])
sage: K.ideal(E.discriminant())
Fractional ideal (90118662980*a + 636812084644)
sage: K.ideal(E.discriminant()).factor()
(Fractional ideal (2))^2 * (Fractional ideal (3, a + 2))^12

Here the minimal discriminant ideal is principal but there is no global minimal model since the quotient is the 12th power of a non-principal ideal:

sage: E.minimal_discriminant_ideal()
Fractional ideal (4)
sage: E.minimal_discriminant_ideal().factor()
(Fractional ideal (2))^2

If (and only if) the curve has everywhere good reduction the result is the unit ideal:

sage: K.<a> = NumberField(x^2-26)
sage: E = EllipticCurve([a,a-1,a+1,4*a+10,2*a+6])
sage: E.conductor()
Fractional ideal (1)
sage: E.discriminant()
-104030*a - 530451
sage: E.minimal_discriminant_ideal()
Fractional ideal (1)

Over \(\QQ\), the result returned is an ideal of \(\ZZ\) rather than a fractional ideal of \(\QQ\):

sage: E = EllipticCurve([1,2,3,4,5])
sage: E.minimal_discriminant_ideal()
Principal ideal (10351) of Integer Ring
non_minimal_primes()

Return a list of primes at which this elliptic curve is not minimal.

OUTPUT:

A list of prime ideals (or prime numbers when the base field is \(\QQ\), empty if this is a global minimal model.

EXAMPLES:

sage: K.<a> = NumberField(x^2-10)
sage: E = EllipticCurve([0, 0, 0, -22500, 750000*a])
sage: E.non_minimal_primes()
[Fractional ideal (2, a), Fractional ideal (5, a)]
sage: K.ideal(E.discriminant()).factor()
(Fractional ideal (2, a))^24 * (Fractional ideal (3, a + 1))^5 * (Fractional ideal (3, a + 2))^5 * (Fractional ideal (5, a))^24 * (Fractional ideal (7))
sage: E.minimal_discriminant_ideal().factor()
(Fractional ideal (2, a))^12 * (Fractional ideal (3, a + 1))^5 * (Fractional ideal (3, a + 2))^5 * (Fractional ideal (7))

Over \(\QQ\), the primes returned are integers, not ideals:

sage: E = EllipticCurve([0,0,0,-3024,46224])
sage: E.non_minimal_primes()
[2, 3]
sage: Emin = E.global_minimal_model()
sage: Emin.non_minimal_primes()
[]

If the model is not globally integral, a ValueError is raised:

sage: E = EllipticCurve([0,0,0,1/2,1/3])
sage: E.non_minimal_primes()
Traceback (most recent call last):
...
ValueError: non_minimal_primes only defined for integral models
period_lattice(embedding)

Return the period lattice of the elliptic curve for the given embedding of its base field with respect to the differential \(dx/(2y + a_1x + a_3)\).

INPUT:

  • embedding - an embedding of the base number field into \(\RR\) or \(\CC\).

Note

The precision of the embedding is ignored: we only use the given embedding to determine which embedding into QQbar to use. Once the lattice has been initialized, periods can be computed to arbitrary precision.

EXAMPLES:

First define a field with two real embeddings:

sage: K.<a> = NumberField(x^3-2)
sage: E = EllipticCurve([0,0,0,a,2])
sage: embs = K.embeddings(CC); len(embs)
3

For each embedding we have a different period lattice:

sage: E.period_lattice(embs[0])
Period lattice associated to Elliptic Curve defined by y^2 = x^3 + a*x + 2 over Number Field in a with defining polynomial x^3 - 2 with respect to the embedding Ring morphism:
From: Number Field in a with defining polynomial x^3 - 2
To:   Algebraic Field
Defn: a |--> -0.6299605249474365? - 1.091123635971722?*I

sage: E.period_lattice(embs[1])
Period lattice associated to Elliptic Curve defined by y^2 = x^3 + a*x + 2 over Number Field in a with defining polynomial x^3 - 2 with respect to the embedding Ring morphism:
From: Number Field in a with defining polynomial x^3 - 2
To:   Algebraic Field
Defn: a |--> -0.6299605249474365? + 1.091123635971722?*I

sage: E.period_lattice(embs[2])
Period lattice associated to Elliptic Curve defined by y^2 = x^3 + a*x + 2 over Number Field in a with defining polynomial x^3 - 2 with respect to the embedding Ring morphism:
From: Number Field in a with defining polynomial x^3 - 2
To:   Algebraic Field
Defn: a |--> 1.259921049894873?

Although the original embeddings have only the default precision, we can obtain the basis with higher precision later:

sage: L=E.period_lattice(embs[0])
sage: L.basis()
(1.86405007647981 - 0.903761485143226*I, -0.149344633143919 - 2.06619546272945*I)

sage: L.basis(prec=100)
(1.8640500764798108425920506200 - 0.90376148514322594749786960975*I, -0.14934463314391922099120107422 - 2.0661954627294548995621225062*I)
rank(**kwds)

Return the rank of this elliptic curve, if it can be determined.

Note

The optional parameters control the Simon two descent algorithm; see the documentation of simon_two_descent() for more details.

INPUT:

  • verbose – 0, 1, 2, or 3 (default: 0), the verbosity level
  • lim1 – (default: 2) limit on trivial points on quartics
  • lim3 – (default: 4) limit on points on ELS quartics
  • limtriv – (default: 2) limit on trivial points on elliptic curve
  • maxprob – (default: 20)
  • limbigprime – (default: 30) to distinguish between small and large prime numbers. Use probabilistic tests for large primes. If 0, do not use probabilistic tests.
  • known_points – (default: None) list of known points on the curve

OUTPUT:

If the upper and lower bounds given by Simon two-descent are the same, then the rank has been uniquely identified and we return this. Otherwise, we raise a ValueError with an error message specifying the upper and lower bounds.

Note

For non-quadratic number fields, this code does return, but it takes a long time.

EXAMPLES:

sage: K.<a> = NumberField(x^2 + 23, 'a')
sage: E = EllipticCurve(K, '37')
sage: E == loads(dumps(E))
True
sage: E.rank()
2

Here is a curve with two-torsion in the Tate-Shafarevich group, so here the bounds given by the algorithm do not uniquely determine the rank:

sage: E = EllipticCurve("15a5")
sage: K.<t> = NumberField(x^2-6)
sage: EK = E.base_extend(K)
sage: EK.rank(lim1=1, lim3=1, limtriv=1)
Traceback (most recent call last):
...
ValueError: There is insufficient data to determine the rank -
2-descent gave lower bound 0 and upper bound 2

IMPLEMENTATION:

Uses Denis Simon’s PARI/GP scripts from http://www.math.unicaen.fr/~simon/.

rank_bounds(**kwds)

Return the lower and upper bounds using simon_two_descent(). The results of simon_two_descent() are cached.

Note

The optional parameters control the Simon two descent algorithm; see the documentation of simon_two_descent() for more details.

INPUT:

  • verbose – 0, 1, 2, or 3 (default: 0), the verbosity level
  • lim1 – (default: 2) limit on trivial points on quartics
  • lim3 – (default: 4) limit on points on ELS quartics
  • limtriv – (default: 2) limit on trivial points on elliptic curve
  • maxprob – (default: 20)
  • limbigprime – (default: 30) to distinguish between small and large prime numbers. Use probabilistic tests for large primes. If 0, do not use probabilistic tests.
  • known_points – (default: None) list of known points on the curve

OUTPUT:

lower and upper bounds for the rank of the Mordell-Weil group

Note

For non-quadratic number fields, this code does return, but it takes a long time.

EXAMPLES:

sage: K.<a> = NumberField(x^2 + 23, 'a')
sage: E = EllipticCurve(K, '37')
sage: E == loads(dumps(E))
True
sage: E.rank_bounds()
(2, 2)

Here is a curve with two-torsion, again the bounds coincide:

sage: Qrt5.<rt5> = NumberField(x^2-5)
sage: E = EllipticCurve([0,5-rt5,0,rt5,0])
sage: E.rank_bounds()
(1, 1)

Finally an example with non-trivial 2-torsion in Sha. So the 2-descent will not be able to determine the rank, but can only give bounds:

sage: E = EllipticCurve("15a5")
sage: K.<t> = NumberField(x^2-6)
sage: EK = E.base_extend(K)
sage: EK.rank_bounds(lim1=1,lim3=1,limtriv=1)
(0, 2)

IMPLEMENTATION:

Uses Denis Simon’s PARI/GP scripts from http://www.math.unicaen.fr/~simon/.

rational_points(**kwds)

Find rational points on the elliptic curve, all arguments are passed on to sage.schemes.generic.algebraic_scheme.rational_points().

EXAMPLES:

sage: E = EllipticCurve('37a')
sage: E.rational_points(bound=8)
[(-1 : -1 : 1),
 (-1 : 0 : 1),
 (0 : -1 : 1),
 (0 : 0 : 1),
 (0 : 1 : 0),
 (1/4 : -5/8 : 1),
 (1/4 : -3/8 : 1),
 (1 : -1 : 1),
 (1 : 0 : 1),
 (2 : -3 : 1),
 (2 : 2 : 1)]

Check that trac ticket #26677 is fixed:

sage: E = EllipticCurve("11a1")
sage: E.rational_points(bound=5)
[(0 : 1 : 0), (5 : 5 : 1)]
sage: E.rational_points(bound=6)
[(0 : 1 : 0), (5 : -6 : 1), (5 : 5 : 1)]

An example over a number field:

sage: E = EllipticCurve([1,0])
sage: pts = E.rational_points(bound = 2, F = QuadraticField(-1))
sage: pts
[(-a : 0 : 1), (0 : 0 : 1), (0 : 1 : 0), (a : 0 : 1)]
sage: pts[0] + pts[1]
(a : 0 : 1)
reducible_primes(algorithm='Billerey', max_l=None, num_l=None, verbose=False)

Return a finite set of primes \(\ell\) for which \(E\) has a K-rational \(\ell\)-isogeny.

For curves without CM the list returned is exactly the finite set of primes \(\ell\) for which the mod-\(\ell\) Galois representation is reducible. For curves with CM this set is infinite; we return a finite list of primes \(\ell\) such that every curve isogenous to this curve can be obtained by a finite sequence of isogenies of degree one of the primes in the list.

INPUT:

  • algorithm (string) – only relevant for non-CM curves. Either ‘Billerey”, to use the methods of [Bil2011], ‘Larson’ to use Larson’s implementation using Galois representations, or ‘heuristic’ (see below).
  • max_l (int or None) – only relevant for non-CM curves and algorithms ‘Billerey’ and ‘heuristic. Controls the maximum prime used in either algorithm. If None, use the default for that algorithm.
  • num_l (int or None) – only relevant for non-CM curves and algorithm ‘Billerey’. Controls the maximum number of primes used in the algorithm. If None, use the default for that algorithm.

Note

The ‘heuristic’ algorithm only checks primes up to the bound max_l. This is faster but not guaranteed to be complete. Both the Billerey and Larson algorithms are rigorous.

EXAMPLES:

sage: K = NumberField(x**2 - 29, 'a'); a = K.gen()
sage: E = EllipticCurve([1, 0, ((5 + a)/2)**2, 0, 0])
sage: rho = E.galois_representation()
sage: rho.reducible_primes()
[3, 5]
sage: E.reducible_primes()
[3, 5]
sage: K = NumberField(x**2 + 1, 'a')
sage: E = EllipticCurve_from_j(K(1728)) # CM over K
sage: rho = E.galois_representation()
sage: rho.reducible_primes() # CM curves always return [0]
[0]
sage: E.reducible_primes()
[2]
sage: E = EllipticCurve_from_j(K(0)) # CM but NOT over K
sage: rho = E.galois_representation()
sage: rho.reducible_primes()
[2, 3]
sage: E.reducible_primes()
[2, 3]
sage: E = EllipticCurve_from_j(K(2268945/128)).global_minimal_model() # c.f. [Sutherland12]
sage: rho = E.galois_representation()
sage: rho.isogeny_bound() # ... but there is no 7-isogeny ...
[7]
sage: rho.reducible_primes()
[]
sage: E.reducible_primes()
[]
reduction(place)

Return the reduction of the elliptic curve at a place of good reduction.

INPUT:

  • place – a prime ideal in the base field of the curve

OUTPUT:

An elliptic curve over a finite field, the residue field of the place.

EXAMPLES:

sage: K.<i> = QuadraticField(-1)
sage: EK = EllipticCurve([0,0,0,i,i+3])
sage: v = K.fractional_ideal(2*i+3)
sage: EK.reduction(v)
Elliptic Curve defined by y^2  = x^3 + 5*x + 8 over Residue field of Fractional ideal (2*i + 3)
sage: EK.reduction(K.ideal(1+i))
Traceback (most recent call last):
...
ValueError: The curve must have good reduction at the place.
sage: EK.reduction(K.ideal(2))
Traceback (most recent call last):
...
ValueError: The ideal must be prime.
sage: K=QQ.extension(x^2+x+1,"a")
sage: E = EllipticCurve([1024*K.0,1024*K.0])
sage: E.reduction(2*K)
Elliptic Curve defined by y^2 + (abar+1)*y = x^3 over Residue field in abar of Fractional ideal (2)
regulator_of_points(points=[], precision=None)

Return the regulator of the given points on this curve.

INPUT:

  • points -(default: empty list) a list of points on this curve
  • precision - int or None (default: None): the precision in bits of the result (default real precision if None)

EXAMPLES:

sage: E = EllipticCurve('37a1')
sage: P = E(0,0)
sage: Q = E(1,0)
sage: E.regulator_of_points([P,Q])
0.000000000000000
sage: 2*P == Q
True
sage: E = EllipticCurve('5077a1')
sage: points = [E.lift_x(x) for x in [-2,-7/4,1]]
sage: E.regulator_of_points(points)
0.417143558758384
sage: E.regulator_of_points(points,precision=100)
0.41714355875838396981711954462
sage: E = EllipticCurve('389a')
sage: E.regulator_of_points()
1.00000000000000
sage: points = [P,Q] = [E(-1,1),E(0,-1)]
sage: E.regulator_of_points(points)
0.152460177943144
sage: E.regulator_of_points(points, precision=100)
0.15246017794314375162432475705
sage: E.regulator_of_points(points, precision=200)
0.15246017794314375162432475704945582324372707748663081784028
sage: E.regulator_of_points(points, precision=300)
0.152460177943143751624324757049455823243727077486630817840280980046053225683562463604114816

Examples over number fields:

sage: K.<a> = QuadraticField(97)
sage: E = EllipticCurve(K,[1,1])
sage: P = E(0,1)
sage: P.height()
0.476223106404866
sage: E.regulator_of_points([P])
0.476223106404866
sage: E = EllipticCurve('11a1')
sage: x = polygen(QQ)
sage: K.<t> = NumberField(x^2+47)
sage: EK = E.base_extend(K)
sage: T = EK(5,5)
sage: T.order()
5
sage: P = EK(-2, -1/2*t - 1/2)
sage: P.order()
+Infinity
sage: EK.regulator_of_points([P,T]) # random very small output
-1.23259516440783e-32
sage: EK.regulator_of_points([P,T]).abs() < 1e-30
True
sage: E = EllipticCurve('389a1')
sage: P,Q = E.gens()
sage: E.regulator_of_points([P,Q])
0.152460177943144
sage: K.<t> = NumberField(x^2+47)
sage: EK = E.base_extend(K)
sage: EK.regulator_of_points([EK(P),EK(Q)])
0.152460177943144
sage: K.<i> = QuadraticField(-1)
sage: E = EllipticCurve([0,0,0,i,i])
sage: P = E(-9+4*i,-18-25*i)
sage: Q = E(i,-i)
sage: E.height_pairing_matrix([P,Q])
[  2.16941934493768 -0.870059380421505]
[-0.870059380421505  0.424585837470709]
sage: E.regulator_of_points([P,Q])
0.164101403936070
saturation(points, verbose=False, max_prime=0, one_prime=0, odd_primes_only=False, lower_ht_bound=None, reg=None, debug=False)

Given a list of rational points on \(E\) over \(K\), compute the saturation in \(E(K)\) of the subgroup they generate.

INPUT:

  • points (list) - list of points on E. Points of finite order are ignored; the remaining points should be independent, or an error is raised.
  • verbose (bool) - (default: False), if True, give verbose output.
  • max_prime (int, default 0), saturation is performed for all primes up to max_prime. If max_prime is 0, perform saturation at all primes, i.e., compute the true saturation.
  • odd_primes_only (bool, default False) – only do saturation at odd primes.
  • one_prime (int, default 0) – if nonzero, only do saturation at this prime.

The following two inputs are optional, and may be provided to speed up the computation.

  • lower_ht_bound (real, default None) – lower bound of the regulator \(E(K)\), if known.
  • reg (real, default None), regulator of the span of points, if known.
  • debug (int, default 0) – , used for debugging and testing.

OUTPUT:

  • saturation (list) - points that form a basis for the saturation.
  • index (int) - the index of the group generated by the input points in their saturation.
  • regulator (real with default precision, or None) - regulator of saturated points.

EXAMPLES:

sage: K.<i> = QuadraticField(-1)
sage: E = EllipticCurve('389a1')
sage: EK = E.change_ring(K)
sage: P = EK(-1,1); Q = EK(0,-1)

sage: EK.saturation([2*P], max_prime=2)
([(-1 : 1 : 1)], 2, 0.686667083305587)
sage: EK.saturation([12*P], max_prime=2)
([(26/361 : -5720/6859 : 1)], 4, 6.18000374975028)
sage: EK.saturation([12*P], lower_ht_bound=0.1)
([(-1 : 1 : 1)], 12, 0.686667083305587)
sage: EK.saturation([2*P, Q], max_prime=2)
([(-1 : 1 : 1), (0 : -1 : 1)], 2, 0.152460177943144)
sage: EK.saturation([P+Q, P-Q], lower_ht_bound=.1, debug=2)
([(-1 : 1 : 1), (1 : 0 : 1)], 2, 0.152460177943144)
sage: EK.saturation([P+Q, 17*Q], lower_ht_bound=0.1)  # long time
([(4 : 8 : 1), (0 : -1 : 1)], 17, 0.152460177943143)

sage: R = EK(i-2,-i-3)
sage: EK.saturation([P+R, P+Q, Q+R], lower_ht_bound=0.1)
([(841/1369*i - 171/1369 : 41334/50653*i - 74525/50653 : 1),
  (4 : 8 : 1),
  (-1/25*i + 18/25 : -69/125*i - 58/125 : 1)],
 2,
 0.103174443217351)
sage: EK.saturation([26*Q], lower_ht_bound=0.1)
([(0 : -1 : 1)], 26, 0.327000773651605)

Another number field:

sage: E = EllipticCurve('389a1')
sage: K.<a> = NumberField(x^3-x+1)
sage: EK = E.change_ring(K)
sage: P = EK(-1,1); Q = EK(0,-1)
sage: EK.saturation([P+Q, P-Q], lower_ht_bound=0.1)
([(-1 : 1 : 1), (1 : 0 : 1)], 2, 0.152460177943144)
sage: EK.saturation([3*P, P+5*Q], lower_ht_bound=0.1)
([(-185/2209 : -119510/103823 : 1), (80041/34225 : -26714961/6331625 : 1)],
 15,
 0.152460177943144)

A different curve:

sage: K.<a> = QuadraticField(3)
sage: E = EllipticCurve('37a1')
sage: EK = E.change_ring(K)
sage: P = EK(0,0); Q = EK(2-a,2*a-4)
sage: EK.saturation([3*P-Q, 3*P+Q], lower_ht_bound=.01)
([(0 : 0 : 1), (1/2*a : -1/4*a - 1/4 : 1)], 6, 0.0317814530725985)

The points must be linearly independent:

sage: EK.saturation([2*P, 3*Q, P-Q])
Traceback (most recent call last):
...
ValueError: points not linearly independent in saturation()

Degenerate case:

sage: EK.saturation([])
([], 1, 1.00000000000000)

ALGORITHM:

For rank 1 subgroups, simply do trial division up to the maximal prime divisor. For higher rank subgroups, perform trial division on all linear combinations for small primes, and look for projections \(E(K) \rightarrow \oplus E(k) \otimes \mathbf{F}_p\) which are either full rank or provide \(p\)-divisible linear combinations, where the \(k\) here are residue fields of \(K\).

simon_two_descent(verbose=0, lim1=2, lim3=4, limtriv=2, maxprob=20, limbigprime=30, known_points=None)

Return lower and upper bounds on the rank of the Mordell-Weil group \(E(K)\) and a list of points.

This method is used internally by the rank(), rank_bounds() and gens() methods.

INPUT:

  • self – an elliptic curve \(E\) over a number field \(K\)
  • verbose – 0, 1, 2, or 3 (default: 0), the verbosity level
  • lim1 – (default: 2) limit on trivial points on quartics
  • lim3 – (default: 4) limit on points on ELS quartics
  • limtriv – (default: 2) limit on trivial points on \(E\)
  • maxprob – (default: 20)
  • limbigprime – (default: 30) to distinguish between small and large prime numbers. Use probabilistic tests for large primes. If 0, do not use probabilistic tests.
  • known_points – (default: None) list of known points on the curve

OUTPUT: a triple (lower, upper, list) consisting of

  • lower (integer) – lower bound on the rank
  • upper (integer) – upper bound on the rank
  • list – list of points in \(E(K)\)

The integer upper is in fact an upper bound on the dimension of the 2-Selmer group, hence on the dimension of \(E(K)/2E(K)\). It is equal to the dimension of the 2-Selmer group except possibly if \(E(K)[2]\) has dimension 1. In that case, upper may exceed the dimension of the 2-Selmer group by an even number, due to the fact that the algorithm does not perform a second descent.

Note

For non-quadratic number fields, this code does return, but it takes a long time.

ALGORITHM:

Uses Denis Simon’s PARI/GP scripts from http://www.math.unicaen.fr/~simon/.

EXAMPLES:

sage: K.<a> = NumberField(x^2 + 23, 'a')
sage: E = EllipticCurve(K, '37')
sage: E == loads(dumps(E))
True
sage: E.simon_two_descent()
(2, 2, [(0 : 0 : 1), (1/8*a + 5/8 : -3/16*a - 7/16 : 1)])
sage: E.simon_two_descent(lim1=3, lim3=20, limtriv=5, maxprob=7, limbigprime=10)
(2, 2, [(-1 : 0 : 1), (-1/8*a + 5/8 : -3/16*a - 9/16 : 1)])
sage: K.<a> = NumberField(x^2 + 7, 'a')
sage: E = EllipticCurve(K, [0,0,0,1,a]); E
Elliptic Curve defined by y^2  = x^3 + x + a over Number Field in a with defining polynomial x^2 + 7

sage: v = E.simon_two_descent(verbose=1); v
 elliptic curve: Y^2 = x^3 + Mod(1, y^2 + 7)*x + Mod(y, y^2 + 7)
 Trivial points on the curve = [[1, 1, 0], [Mod(1/2*y + 3/2, y^2 + 7), Mod(-y - 2, y^2 + 7), 1]]
#S(E/K)[2]    = 2
#E(K)/2E(K)   = 2
#III(E/K)[2]  = 1
rank(E/K)     = 1
 listpoints = [[Mod(1/2*y + 3/2, y^2 + 7), Mod(-y - 2, y^2 + 7), 1]]
(1, 1, [(1/2*a + 3/2 : -a - 2 : 1)])

sage: v = E.simon_two_descent(verbose=2)
K = bnfinit(y^2 + 7);
a = Mod(y,K.pol);
bnfellrank(K, [0, 0, 0, 1, a], [[Mod(1/2*y + 3/2, y^2 + 7), Mod(-y - 2, y^2 + 7)]]);
 elliptic curve: Y^2 = x^3 + Mod(1, y^2 + 7)*x + Mod(y, y^2 + 7)
  A = Mod(0, y^2 + 7)
  B = Mod(1, y^2 + 7)
  C = Mod(y, y^2 + 7)

  Computing L(S,2)
  L(S,2) = [Mod(Mod(-1/2*y + 1/2, y^2 + 7)*x^2 + Mod(-1/2*y - 1/2, y^2 + 7)*x + Mod(-y - 1, y^2 + 7), x^3 + Mod(1, y^2 + 7)*x + Mod(y, y^2 + 7)), Mod(-x^2 + Mod(-1/2*y - 1/2, y^2 + 7)*x + 1, x^3 + Mod(1, y^2 + 7)*x + Mod(y, y^2 + 7)), Mod(-1, x^3 + Mod(1, y^2 + 7)*x + Mod(y, y^2 + 7)), Mod(x^2 + 2, x^3 + Mod(1, y^2 + 7)*x + Mod(y, y^2 + 7)), Mod(x + Mod(1/2*y + 3/2, y^2 + 7), x^3 + Mod(1, y^2 + 7)*x + Mod(y, y^2 + 7)), Mod(x + Mod(1/2*y - 3/2, y^2 + 7), x^3 + Mod(1, y^2 + 7)*x + Mod(y, y^2 + 7))]

  Computing the Selmer group
  #LS2gen = 2
   LS2gen = [Mod(Mod(-1/2*y + 1/2, y^2 + 7)*x^2 + Mod(-1/2*y - 1/2, y^2 + 7)*x + Mod(-y - 1, y^2 + 7), x^3 + Mod(1, y^2 + 7)*x + Mod(y, y^2 + 7)), Mod(x^2 + Mod(1/2*y + 1/2, y^2 + 7)*x - 1, x^3 + Mod(1, y^2 + 7)*x + Mod(y, y^2 + 7))]
  Search for trivial points on the curve
 Trivial points on the curve = [[Mod(1/2*y + 3/2, y^2 + 7), Mod(-y - 2, y^2 + 7)], [1, 1, 0], [Mod(1/2*y + 3/2, y^2 + 7), Mod(-y - 2, y^2 + 7), 1]]
  zc = Mod(Mod(-1/2*y + 1/2, y^2 + 7)*x^2 + Mod(-1/2*y - 1/2, y^2 + 7)*x + Mod(-y - 1, y^2 + 7), x^3 + Mod(1, y^2 + 7)*x + Mod(y, y^2 + 7))
  Hilbert symbol (Mod(1, y^2 + 7),Mod(-2*y + 2, y^2 + 7)) =
  sol of quadratic equation = [1, 1, 0]~
  zc*z1^2 = Mod(4*x + Mod(-2*y + 6, y^2 + 7), x^3 + Mod(1, y^2 + 7)*x + Mod(y, y^2 + 7))
  quartic: (-1)*Y^2 = x^4 + (3*y - 9)*x^2 + (-8*y + 16)*x + (9/2*y - 11/2)
  reduced: Y^2 = -x^4 + (-3*y + 9)*x^2 + (-8*y + 16)*x + (-9/2*y + 11/2)
  not ELS at [2, [0, 1]~, 1, 1, [1, -2; 1, 0]]
  zc = Mod(Mod(1, y^2 + 7)*x^2 + Mod(1/2*y + 1/2, y^2 + 7)*x + Mod(-1, y^2 + 7), x^3 + Mod(1, y^2 + 7)*x + Mod(y, y^2 + 7))
  comes from the trivial point [Mod(1/2*y + 3/2, y^2 + 7), Mod(-y - 2, y^2 + 7)]
  m1 = 1
  m2 = 1
#S(E/K)[2]    = 2
#E(K)/2E(K)   = 2
#III(E/K)[2]  = 1
rank(E/K)     = 1
 listpoints = [[Mod(1/2*y + 3/2, y^2 + 7), Mod(-y - 2, y^2 + 7)]]
v = [1, 1, [[Mod(1/2*y + 3/2, y^2 + 7), Mod(-y - 2, y^2 + 7)]]]
sage: v
(1, 1, [(1/2*a + 3/2 : -a - 2 : 1)])

A curve with 2-torsion:

sage: K.<a> = NumberField(x^2 + 7)
sage: E = EllipticCurve(K, '15a')
sage: E.simon_two_descent()  # long time (3s on sage.math, 2013), points can vary
(1, 3, [...])

Check that the bug reported in trac ticket #15483 is fixed:

sage: K.<s> = QuadraticField(229)
sage: c4 = 2173 - 235*(1 - s)/2
sage: c6 = -124369 + 15988*(1 - s)/2
sage: E = EllipticCurve([-c4/48, -c6/864])
sage: E.simon_two_descent()
(0, 0, [])

sage: R.<t> = QQ[]
sage: L.<g> = NumberField(t^3 - 9*t^2 + 13*t - 4)
sage: E1 = EllipticCurve(L,[1-g*(g-1),-g^2*(g-1),-g^2*(g-1),0,0])
sage: E1.rank()  # long time (about 5 s)
0

sage: K = CyclotomicField(43).subfields(3)[0][0]
sage: E = EllipticCurve(K, '37')
sage: E.simon_two_descent()  # long time (4s on sage.math, 2013)
(3,
 3,
 [(0 : 0 : 1),
  (-1/2*zeta43_0^2 - 1/2*zeta43_0 + 7 : -3/2*zeta43_0^2 - 5/2*zeta43_0 + 18 : 1)])
tamagawa_exponent(P, proof=None)

Return the Tamagawa index of this elliptic curve at the prime \(P\).

INPUT:

  • P – either None or a prime ideal of the base field of self.
  • proof – whether to only use provably correct methods (default controlled by global proof module). Note that the proof module is number_field, not elliptic_curves, since the functions that actually need the flag are in number fields.

OUTPUT:

(positive integer) The Tamagawa index of the curve at P.

EXAMPLES:

sage: K.<a> = NumberField(x^2-5)
sage: E = EllipticCurve([20, 225, 750, 625*a + 6875, 31250*a + 46875])
sage: [E.tamagawa_exponent(P) for P in E.discriminant().support()]
[1, 1, 1, 1]
sage: K.<a> = QuadraticField(-11)
sage: E = EllipticCurve('11a1').change_ring(K)
sage: [E.tamagawa_exponent(P) for P in K(11).support()]
[10]
tamagawa_number(P, proof=None)

Return the Tamagawa number of this elliptic curve at the prime \(P\).

INPUT:

  • P – either None or a prime ideal of the base field of self.
  • proof – whether to only use provably correct methods (default controlled by global proof module). Note that the proof module is number_field, not elliptic_curves, since the functions that actually need the flag are in number fields.

OUTPUT:

(positive integer) The Tamagawa number of the curve at \(P\).

EXAMPLES:

sage: K.<a> = NumberField(x^2-5)
sage: E = EllipticCurve([20, 225, 750, 625*a + 6875, 31250*a + 46875])
sage: [E.tamagawa_number(P) for P in E.discriminant().support()]
[1, 1, 1, 1]
sage: K.<a> = QuadraticField(-11)
sage: E = EllipticCurve('11a1').change_ring(K)
sage: [E.tamagawa_number(P) for P in K(11).support()]
[10]
tamagawa_numbers()

Return a list of all Tamagawa numbers for all prime divisors of the conductor (in order).

EXAMPLES:

sage: e = EllipticCurve('30a1')
sage: e.tamagawa_numbers()
[2, 3, 1]
sage: vector(e.tamagawa_numbers())
(2, 3, 1)
sage: K.<a> = NumberField(x^2+3)
sage: eK = e.base_extend(K)
sage: eK.tamagawa_numbers()
[4, 6, 1]
tamagawa_product_bsd()

Given an elliptic curve \(E\) over a number field \(K\), this function returns the integer \(C(E/K)\) that appears in the Birch and Swinnerton-Dyer conjecture accounting for the local information at finite places. If the model is a global minimal model then \(C(E/K)\) is simply the product of the Tamagawa numbers \(c_v\) where \(v\) runs over all prime ideals of \(K\). Otherwise, if the model has to be changed at a place \(v\) a correction factor appears. The definition is such that \(C(E/K)\) times the periods at the infinite places is invariant under change of the Weierstrass model. See [Tate1966] and [DD2010] for details.

Note

This definition is slightly different from the definition of tamagawa_product for curves defined over \(\QQ\). Over the rational number it is always defined to be the product of the Tamagawa numbers, so the two definitions only agree when the model is global minimal.

OUTPUT:

A rational number

EXAMPLES:

sage: K.<i> = NumberField(x^2+1)
sage: E = EllipticCurve([0,2+i])
sage: E.tamagawa_product_bsd()
1

sage: E = EllipticCurve([(2*i+1)^2,i*(2*i+1)^7])
sage: E.tamagawa_product_bsd()
4

An example where the Neron model changes over K:

sage: K.<t> = NumberField(x^5-10*x^3+5*x^2+10*x+1)
sage: E = EllipticCurve(K,'75a1')
sage: E.tamagawa_product_bsd()
5
sage: da = E.local_data()
sage: [dav.tamagawa_number() for dav in da]
[1, 1]

An example over \(\QQ\) (trac ticket #9413):

sage: E = EllipticCurve('30a')
sage: E.tamagawa_product_bsd()
6
torsion_order()

Return the order of the torsion subgroup of this elliptic curve.

OUTPUT:

(integer) the order of the torsion subgroup of this elliptic curve.

EXAMPLES:

sage: E = EllipticCurve('11a1')
sage: K.<t> = NumberField(x^4 + x^3 + 11*x^2 + 41*x + 101)
sage: EK = E.base_extend(K)
sage: EK.torsion_order()  # long time (2s on sage.math, 2014)
25
sage: E = EllipticCurve('15a1')
sage: K.<t> = NumberField(x^2 + 2*x + 10)
sage: EK = E.base_extend(K)
sage: EK.torsion_order()
16
sage: E = EllipticCurve('19a1')
sage: K.<t> = NumberField(x^9-3*x^8-4*x^7+16*x^6-3*x^5-21*x^4+5*x^3+7*x^2-7*x+1)
sage: EK = E.base_extend(K)
sage: EK.torsion_order()
9
sage: K.<i> = QuadraticField(-1)
sage: EK = EllipticCurve([0,0,0,i,i+3])
sage: EK.torsion_order()
1
torsion_points()

Return a list of the torsion points of this elliptic curve.

OUTPUT:

(list) A sorted list of the torsion points.

EXAMPLES:

sage: E = EllipticCurve('11a1')
sage: E.torsion_points()
[(0 : 1 : 0), (5 : -6 : 1), (5 : 5 : 1), (16 : -61 : 1), (16 : 60 : 1)]
sage: K.<t> = NumberField(x^4 + x^3 + 11*x^2 + 41*x + 101)
sage: EK = E.base_extend(K)
sage: EK.torsion_points()  # long time (1s on sage.math, 2014)
[(0 : 1 : 0),
 (16 : 60 : 1),
 (5 : 5 : 1),
 (5 : -6 : 1),
 (16 : -61 : 1),
 (t : 1/11*t^3 + 6/11*t^2 + 19/11*t + 48/11 : 1),
 (-3/55*t^3 - 7/55*t^2 - 2/55*t - 133/55 : 6/55*t^3 + 3/55*t^2 + 25/11*t + 156/55 : 1),
 (-9/121*t^3 - 21/121*t^2 - 127/121*t - 377/121 : -7/121*t^3 + 24/121*t^2 + 197/121*t + 16/121 : 1),
 (5/121*t^3 - 14/121*t^2 - 158/121*t - 453/121 : -49/121*t^3 - 129/121*t^2 - 315/121*t - 207/121 : 1),
 (10/121*t^3 + 49/121*t^2 + 168/121*t + 73/121 : 32/121*t^3 + 60/121*t^2 - 261/121*t - 807/121 : 1),
 (1/11*t^3 - 5/11*t^2 + 19/11*t - 40/11 : -6/11*t^3 - 3/11*t^2 - 26/11*t - 321/11 : 1),
 (14/121*t^3 - 15/121*t^2 + 90/121*t + 232/121 : 16/121*t^3 - 69/121*t^2 + 293/121*t - 46/121 : 1),
 (3/55*t^3 + 7/55*t^2 + 2/55*t + 78/55 : 7/55*t^3 - 24/55*t^2 + 9/11*t + 17/55 : 1),
 (-5/121*t^3 + 36/121*t^2 - 84/121*t + 24/121 : 34/121*t^3 - 27/121*t^2 + 305/121*t + 708/121 : 1),
 (-26/121*t^3 + 20/121*t^2 - 219/121*t - 995/121 : 15/121*t^3 + 156/121*t^2 - 232/121*t + 2766/121 : 1),
 (1/11*t^3 - 5/11*t^2 + 19/11*t - 40/11 : 6/11*t^3 + 3/11*t^2 + 26/11*t + 310/11 : 1),
 (-26/121*t^3 + 20/121*t^2 - 219/121*t - 995/121 : -15/121*t^3 - 156/121*t^2 + 232/121*t - 2887/121 : 1),
 (-5/121*t^3 + 36/121*t^2 - 84/121*t + 24/121 : -34/121*t^3 + 27/121*t^2 - 305/121*t - 829/121 : 1),
 (3/55*t^3 + 7/55*t^2 + 2/55*t + 78/55 : -7/55*t^3 + 24/55*t^2 - 9/11*t - 72/55 : 1),
 (14/121*t^3 - 15/121*t^2 + 90/121*t + 232/121 : -16/121*t^3 + 69/121*t^2 - 293/121*t - 75/121 : 1),
 (t : -1/11*t^3 - 6/11*t^2 - 19/11*t - 59/11 : 1),
 (10/121*t^3 + 49/121*t^2 + 168/121*t + 73/121 : -32/121*t^3 - 60/121*t^2 + 261/121*t + 686/121 : 1),
 (5/121*t^3 - 14/121*t^2 - 158/121*t - 453/121 : 49/121*t^3 + 129/121*t^2 + 315/121*t + 86/121 : 1),
 (-9/121*t^3 - 21/121*t^2 - 127/121*t - 377/121 : 7/121*t^3 - 24/121*t^2 - 197/121*t - 137/121 : 1),
 (-3/55*t^3 - 7/55*t^2 - 2/55*t - 133/55 : -6/55*t^3 - 3/55*t^2 - 25/11*t - 211/55 : 1)]
sage: E = EllipticCurve('15a1')
sage: K.<t> = NumberField(x^2 + 2*x + 10)
sage: EK = E.base_extend(K)
sage: EK.torsion_points()
[(-7 : -5*t - 2 : 1),
 (-7 : 5*t + 8 : 1),
 (-13/4 : 9/8 : 1),
 (-2 : -2 : 1),
 (-2 : 3 : 1),
 (-t - 2 : -t - 7 : 1),
 (-t - 2 : 2*t + 8 : 1),
 (-1 : 0 : 1),
 (t : t - 5 : 1),
 (t : -2*t + 4 : 1),
 (0 : 1 : 0),
 (1/2 : -5/4*t - 2 : 1),
 (1/2 : 5/4*t + 1/2 : 1),
 (3 : -2 : 1),
 (8 : -27 : 1),
 (8 : 18 : 1)]
sage: K.<i> = QuadraticField(-1)
sage: EK = EllipticCurve(K,[0,0,0,0,-1])
sage: EK.torsion_points ()
 [(-2 : -3*i : 1), (-2 : 3*i : 1), (0 : -i : 1), (0 : i : 1), (0 : 1 : 0), (1 : 0 : 1)]
torsion_subgroup()

Return the torsion subgroup of this elliptic curve.

OUTPUT:

(EllipticCurveTorsionSubgroup) The EllipticCurveTorsionSubgroup associated to this elliptic curve.

EXAMPLES:

sage: E = EllipticCurve('11a1')
sage: K.<t> = NumberField(x^4 + x^3 + 11*x^2 + 41*x + 101)
sage: EK = E.base_extend(K)
sage: tor = EK.torsion_subgroup()  # long time (2s on sage.math, 2014)
sage: tor  # long time
Torsion Subgroup isomorphic to Z/5 + Z/5 associated to the Elliptic Curve defined by y^2 + y = x^3 + (-1)*x^2 + (-10)*x + (-20) over Number Field in t with defining polynomial x^4 + x^3 + 11*x^2 + 41*x + 101
sage: tor.gens()  # long time
((16 : 60 : 1), (t : 1/11*t^3 + 6/11*t^2 + 19/11*t + 48/11 : 1))
sage: E = EllipticCurve('15a1')
sage: K.<t> = NumberField(x^2 + 2*x + 10)
sage: EK = E.base_extend(K)
sage: EK.torsion_subgroup()
Torsion Subgroup isomorphic to Z/4 + Z/4 associated to the Elliptic Curve defined by y^2 + x*y + y = x^3 + x^2 + (-10)*x + (-10) over Number Field in t with defining polynomial x^2 + 2*x + 10
sage: E = EllipticCurve('19a1')
sage: K.<t> = NumberField(x^9-3*x^8-4*x^7+16*x^6-3*x^5-21*x^4+5*x^3+7*x^2-7*x+1)
sage: EK = E.base_extend(K)
sage: EK.torsion_subgroup()
Torsion Subgroup isomorphic to Z/9 associated to the Elliptic Curve defined by y^2 + y = x^3 + x^2 + (-9)*x + (-15) over Number Field in t with defining polynomial x^9 - 3*x^8 - 4*x^7 + 16*x^6 - 3*x^5 - 21*x^4 + 5*x^3 + 7*x^2 - 7*x + 1
sage: K.<i> = QuadraticField(-1)
sage: EK = EllipticCurve([0,0,0,i,i+3])
sage: EK.torsion_subgroup ()
Torsion Subgroup isomorphic to Trivial group associated to the Elliptic Curve defined by y^2  = x^3 + i*x + (i+3) over Number Field in i with defining polynomial x^2 + 1