# Points on projective varieties¶

Scheme morphism for points on projective varieties

AUTHORS:

• David Kohel, William Stein
• William Stein (2006-02-11): fixed bug where P(0,0,0) was allowed as a projective point.
• Volker Braun (2011-08-08): Renamed classes, more documentation, misc cleanups.
• Ben Hutz (June 2012) added support for projective ring; (March 2013) iteration functionality and new directory structure for affine/projective, height functionality
class sage.schemes.projective.projective_point.SchemeMorphism_point_abelian_variety_field(X, v, check=True)

A rational point of an abelian variety over a field.

EXAMPLES:

sage: E = EllipticCurve([0,0,1,-1,0])
sage: origin = E(0)
sage: origin.domain()
Spectrum of Rational Field
sage: origin.codomain()
Elliptic Curve defined by y^2 + y = x^3 - x over Rational Field
class sage.schemes.projective.projective_point.SchemeMorphism_point_projective_field(X, v, check=True)

A rational point of projective space over a field.

INPUT:

• X – a homset of a subscheme of an ambient projective space over a field $$K$$.
• v – a list or tuple of coordinates in $$K$$.
• check – boolean (optional, default:True). Whether to check the input for consistency.

EXAMPLES:

sage: P = ProjectiveSpace(3, RR)
sage: P(2, 3, 4, 5)
(0.400000000000000 : 0.600000000000000 : 0.800000000000000 : 1.00000000000000)
clear_denominators()

scales by the least common multiple of the denominators.

OUTPUT: None.

EXAMPLES:

sage: R.<t> = PolynomialRing(QQ)
sage: P.<x,y,z> = ProjectiveSpace(FractionField(R), 2)
sage: Q = P([t, 3/t^2, 1])
sage: Q.clear_denominators(); Q
(t^3 : 3 : t^2)
sage: R.<x> = PolynomialRing(QQ)
sage: K.<w> = NumberField(x^2 - 3)
sage: P.<x,y,z> = ProjectiveSpace(K, 2)
sage: Q = P([1/w, 3, 0])
sage: Q.clear_denominators(); Q
(w : 9 : 0)
sage: P.<x,y,z> = ProjectiveSpace(QQ, 2)
sage: X = P.subscheme(x^2 - y^2);
sage: Q = X([1/2, 1/2, 1]);
sage: Q.clear_denominators(); Q
(1 : 1 : 2)
sage: PS.<x,y> = ProjectiveSpace(QQ, 1)
sage: Q = PS.point([1, 2/3], False); Q
(1 : 2/3)
sage: Q.clear_denominators(); Q
(3 : 2)
intersection_multiplicity(X)

Return the intersection multiplicity of the codomain of this point and X at this point.

This uses the intersection_multiplicity implementations for projective/affine subschemes. This point must be a point of a projective subscheme.

INPUT:

• X – a subscheme in the same ambient space as that of the codomain of this point.

OUTPUT: Integer.

EXAMPLES:

sage: P.<x,y,z,w> = ProjectiveSpace(QQ, 3)
sage: X = P.subscheme([x*z - y^2])
sage: Y = P.subscheme([x^3 - y*w^2 + z*w^2, x*y - z*w])
sage: Q1 = X([1/2, 1/4, 1/8, 1])
sage: Q1.intersection_multiplicity(Y)
1
sage: Q2 = X([0,0,0,1])
sage: Q2.intersection_multiplicity(Y)
5
sage: Q3 = X([0,0,1,0])
sage: Q3.intersection_multiplicity(Y)
6
sage: P.<x,y,z,w> = ProjectiveSpace(QQ, 3)
sage: X = P.subscheme([x^2 - y^2])
sage: Q = P([1,1,1,0])
sage: Q.intersection_multiplicity(X)
Traceback (most recent call last):
...
TypeError: this point must be a point on a projective subscheme
multiplicity()

Return the multiplicity of this point on its codomain.

Uses the subscheme multiplicity implementation. This point must be a point on a projective subscheme.

OUTPUT: an integer.

EXAMPLES:

sage: P.<x,y,z,w,t> = ProjectiveSpace(QQ, 4)
sage: X = P.subscheme([y^6 - x^3*w^2*t + t^5*w, x^2 - t^2])
sage: Q1 = X([1,0,2,1,1])
sage: Q1.multiplicity()
1
sage: Q2 = X([0,0,-2,1,0])
sage: Q2.multiplicity()
8
normalize_coordinates()

Normalizes the point so that the last non-zero coordinate is $$1$$.

OUTPUT: None.

EXAMPLES:

sage: P.<x,y,z> = ProjectiveSpace(GF(5),2)
sage: Q = P.point([GF(5)(1), GF(5)(3), GF(5)(0)], False); Q
(1 : 3 : 0)
sage: Q.normalize_coordinates(); Q
(2 : 1 : 0)
sage: P.<x,y,z> = ProjectiveSpace(QQ, 2)
sage: X = P.subscheme(x^2-y^2);
sage: Q = X.point([23, 23, 46], False); Q
(23 : 23 : 46)
sage: Q.normalize_coordinates(); Q
(1/2 : 1/2 : 1)
class sage.schemes.projective.projective_point.SchemeMorphism_point_projective_finite_field(X, v, check=True)
orbit_structure(f)

This function returns the pair $$[m,n]$$ where $$m$$ is the preperiod and $$n$$ is the period of the point by the map f.

Every point is preperiodic over a finite field so this is always possible.

INPUT:

• f – a ScemeMorphism_polynomial with this point in f.domain().

OUTPUT:

• a list $$[m,n]$$ of integers.

EXAMPLES:

sage: P.<x,y,z> = ProjectiveSpace(GF(5),2)
sage: f = DynamicalSystem_projective([x^2 + y^2, y^2, z^2 + y*z], domain=P)
sage: P(1, 0, 1).orbit_structure(f)
doctest:warning
...
[0, 1]
class sage.schemes.projective.projective_point.SchemeMorphism_point_projective_ring(X, v, check=True)

A rational point of projective space over a ring.

INPUT:

• X – a homset of a subscheme of an ambient projective space over a ring $$K$$.
• v – a list or tuple of coordinates in $$K$$.
• check – boolean (optional, default:True). Whether to check the input for consistency.

EXAMPLES:

sage: P = ProjectiveSpace(2, ZZ)
sage: P(2,3,4)
(2 : 3 : 4)
canonical_height(F, **kwds)

Evaluates the (absolute) canonical height of this point with respect to the map F.

Must be over number field or order of a number field or QQbar. Specify either the number of terms of the series to evaluate or the error bound required.

ALGORITHM:

The sum of the Green’s function at the archimedean places and the places of bad reduction.

If function is defined over QQ uses Wells’ Algorithm, which allows us to not have to factor the resultant.

INPUT:

• F - a projective morphism.

kwds:

• N - positive integer. number of terms of the series to use in the local green functions. (optional - default:10)
• prec - positive integer, float point or p-adic precision, default:100.
• error_bound - a positive real number (optional).

OUTPUT: a real number.

AUTHORS:

• Original algorithm written by Elliot Wells [WELLS]
• Wells’ Algorithm implemented as part of GSOC 2017 by Rebecca Lauren Miller and Paul Fili

EXAMPLES:

sage: P.<x,y> = ProjectiveSpace(QQ, 1)
sage: f = DynamicalSystem_projective([1000*x^2-29*y^2, 1000*y^2], domain=P)
sage: Q = P(-1/4, 1)
sage: Q.canonical_height(f, error_bound=0.01)
doctest:warning
...
3.7996079979254623065837411853
sage: RSA768 = 123018668453011775513049495838496272077285356959533479219732245215\
1726400507263657518745202199786469389956474942774063845925192557326303453731548\
2685079170261221429134616704292143116022212404792747377940806653514195974598569\
02143413
sage: P.<x,y> = ProjectiveSpace(QQ,1)
sage: H = End(P)
sage: f = H([RSA768*x^2 + y^2, x*y])
sage: Q = P(RSA768,1)
sage: Q.canonical_height(f, error_bound=0.00000000000000001)
doctest:warning
...
931.18256422718241278672729195
dehomogenize(n)

Dehomogenizes at the nth coordinate.

INPUT:

• n – non-negative integer.

OUTPUT:

• SchemeMorphism_point_affine.

EXAMPLES:

sage: P.<x,y,z> = ProjectiveSpace(QQ,2)
sage: X = P.subscheme(x^2-y^2);
sage: Q = X(23, 23, 46)
sage: Q.dehomogenize(2)
(1/2, 1/2)
sage: R.<t> = PolynomialRing(QQ)
sage: S = R.quo(R.ideal(t^3))
sage: P.<x,y,z> = ProjectiveSpace(S,2)
sage: Q = P(t, 1, 1)
sage: Q.dehomogenize(1)
(tbar, 1)
sage: P.<x,y,z> = ProjectiveSpace(GF(5),2)
sage: Q = P(1, 3, 1)
sage: Q.dehomogenize(0)
(3, 1)
sage: P.<x,y,z>=  ProjectiveSpace(GF(5),2)
sage: Q = P(1, 3, 0)
sage: Q.dehomogenize(2)
Traceback (most recent call last):
...
ValueError: can't dehomogenize at 0 coordinate
global_height(prec=None)

Returns the absolute logarithmic height of the point.

INPUT:

• prec – desired floating point precision (default: default RealField precision).

OUTPUT:

• a real number.

EXAMPLES:

sage: P.<x,y,z> = ProjectiveSpace(QQ,2)
sage: Q = P.point([4, 4, 1/30])
sage: Q.global_height()
4.78749174278205
sage: P.<x,y,z> = ProjectiveSpace(ZZ,2)
sage: Q = P([4, 1, 30])
sage: Q.global_height()
3.40119738166216
sage: R.<x> = PolynomialRing(QQ)
sage: k.<w> = NumberField(x^2+5)
sage: A = ProjectiveSpace(k, 2, 'z')
sage: A([3, 5*w+1, 1]).global_height(prec=100)
2.4181409534757389986565376694
sage: P.<x,y,z> = ProjectiveSpace(QQbar,2)
sage: Q = P([QQbar(sqrt(3)), QQbar(sqrt(-2)), 1])
sage: Q.global_height()
0.549306144334055
green_function(G, v, **kwds)

Evaluates the local Green’s function with respect to the morphism G at the place v for this point with N terms of the series or to within a given error bound.

Must be over a number field or order of a number field. Note that this is the absolute local Green’s function so is scaled by the degree of the base field.

Use v=0 for the archimedean place over $$\QQ$$ or field embedding. Non-archimedean places are prime ideals for number fields or primes over $$\QQ$$.

ALGORITHM:

See Exercise 5.29 and Figure 5.6 of [Sil2007].

INPUT:

• G - a projective morphism whose local Green’s function we are computing.
• v - non-negative integer. a place, use v=0 for the archimedean place.

kwds:

• N - positive integer. number of terms of the series to use, default: 10.
• prec - positive integer, float point or p-adic precision, default: 100.
• error_bound - a positive real number.

OUTPUT:

• a real number.

EXAMPLES:

sage: P.<x,y> = ProjectiveSpace(QQ,1)
sage: H = Hom(P,P)
sage: f = H([x^2+y^2, x*y]);
sage: Q = P(5, 1)
sage: Q.green_function(f, 0, N=200, prec=200)
doctest:warning
...
1.6460930160038721802875250367738355497198064992657997569827
is_preperiodic(f, err=0.1, return_period=False)

Determine if the point is preperiodic with respect to the map f.

This is only implemented for projective space (not subschemes). There are two optional keyword arguments: error_bound sets the error_bound used in the canonical height computation and return_period a boolean which controls if the period is returned if the point is preperiodic. If return_period is True and this point is not preperiodic, then $$(0,0)$$ is returned for the period.

ALGORITHM:

We know that a point is preperiodic if and only if it has canonical height zero. However, we can only compute the canonical height up to numerical precision. This function first computes the canonical height of the point to the given error bound. If it is larger than that error bound, then it must not be preperiodic. If it is less than the error bound, then we expect preperiodic. In this case we begin computing the orbit stopping if either we determine the orbit is finite, or the height of the point is large enough that it must be wandering. We can determine the height cutoff by computing the height difference constant, i.e., the bound between the height and the canonical height of a point (which depends only on the map and not the point itself). If the height of the point is larger than the difference bound, then the canonical height cannot be zero so the point cannot be preperiodic.

INPUT:

• f – an endomorphism of this point’s codomain.

kwds:

• error_bound – a positive real number (optional - default: 0.1).
• return_period – boolean (optional - default: False).

OUTPUT:

• boolean – True if preperiodic.
• if return_period is True, then (0,0) if wandering, and (m,n)
if preperiod m and period n.

EXAMPLES:

sage: P.<x,y> = ProjectiveSpace(QQ,1)
sage: f = DynamicalSystem_projective([x^3-3*x*y^2, y^3], domain=P)
sage: Q = P(-1, 1)
sage: Q.is_preperiodic(f)
True
sage: P.<x,y> = ProjectiveSpace(QQ,1)
sage: f = DynamicalSystem_projective([x^2-29/16*y^2, y^2], domain=P)
sage: Q = P(1, 4)
sage: Q.is_preperiodic(f, return_period=True)
(1, 3)
sage: Q = P(1, 1)
sage: Q.is_preperiodic(f, return_period=True)
(0, 0)
sage: R.<x> = PolynomialRing(QQ)
sage: K.<a> = NumberField(x^2+1)
sage: P.<x,y> = ProjectiveSpace(K, 1)
sage: f = DynamicalSystem_projective([x^5 + 5/4*x*y^4, y^5], domain=P)
sage: Q = P([-1/2*a+1/2, 1])
sage: Q.is_preperiodic(f)
True
sage: Q = P([a, 1])
sage: Q.is_preperiodic(f)
False
sage: P.<x,y,z> = ProjectiveSpace(QQ,2)
sage: f = DynamicalSystem_projective([-38/45*x^2 + (2*y - 7/45*z)*x + (-1/2*y^2 - 1/2*y*z + z^2),\
-67/90*x^2 + (2*y + z*157/90)*x - y*z, z^2], domain=P)
sage: Q = P([1, 3, 1])
sage: Q.is_preperiodic(f, return_period=True)
(0, 9)
sage: P.<x,y,z,w> = ProjectiveSpace(QQ,3)
sage: f = DynamicalSystem_projective([(-y - w)*x + (-13/30*y^2 + 13/30*w*y + w^2),\
-1/2*x^2 + (-y + 3/2*w)*x + (-1/3*y^2 + 4/3*w*y),-3/2*z^2 + 5/2*z*w + w^2,w^2], domain=P)
sage: Q = P([3,0,4/3,1])
sage: Q.is_preperiodic(f, return_period=True)
(2, 24)
sage: set_verbose(-1)
sage: P.<x,y,z> = ProjectiveSpace(QQbar,2)
sage: f = DynamicalSystem_projective([x^2, QQbar(sqrt(-1))*y^2, z^2], domain=P)
sage: Q = P([1, 1, 1])
sage: Q.is_preperiodic(f)
True
sage: set_verbose(-1)
sage: P.<x,y,z> = ProjectiveSpace(QQbar,2)
sage: f = DynamicalSystem_projective([x^2, y^2, z^2], domain=P)
sage: Q = P([QQbar(sqrt(-1)), 1, 1])
sage: Q.is_preperiodic(f)
True
sage: P.<x,y> = ProjectiveSpace(QQ, 1)
sage: f = DynamicalSystem_projective([16*x^2-29*y^2, 16*y^2], domain=P)
sage: Q = P(-1,4)
sage: Q.is_preperiodic(f)
True
sage: P.<x,y> = ProjectiveSpace(QQ, 1)
sage: H = End(P)
sage: f = H([16*x^2-29*y^2, 16*y^2])
sage: Q = P(-1,4)
sage: Q.is_preperiodic(f)
Traceback (most recent call last):
...
TypeError: map must be a dynamical system
local_height(v, prec=None)

Returns the maximum of the local height of the coordinates of this point.

INPUT:

• v – a prime or prime ideal of the base ring.
• prec – desired floating point precision (default: default RealField precision).

OUTPUT:

• a real number.

EXAMPLES:

sage: P.<x,y,z>=  ProjectiveSpace(QQ,2)
sage: Q = P.point([4,4,1/150], False)
sage: Q.local_height(5)
3.21887582486820
sage: P.<x,y,z> = ProjectiveSpace(QQ,2)
sage: Q = P([4, 1, 30])
sage: Q.local_height(2)
0.693147180559945
local_height_arch(i, prec=None)

Returns the maximum of the local heights at the i-th infinite place of this point.

INPUT:

• i – an integer.
• prec – desired floating point precision (default: default RealField precision).

OUTPUT:

• a real number.

EXAMPLES:

sage: P.<x,y,z> = ProjectiveSpace(QQ,2)
sage: Q = P.point([4, 4, 1/150], False)
sage: Q.local_height_arch(0)
1.38629436111989
sage: P.<x,y,z> = ProjectiveSpace(QuadraticField(5, 'w'), 2)
sage: Q = P.point([4, 1, 30], False)
sage: Q.local_height_arch(1)
3.401197381662155375413236691607
multiplier(f, n, check=True)

Returns the multiplier of this point of period n by the function f.

f must be an endomorphism of projective space.

INPUT:

• f - a endomorphism of this point’s codomain.
• n - a positive integer, the period of this point.
• check – check if P is periodic of period n, Default:True.

OUTPUT:

• a square matrix of size self.codomain().dimension_relative() in the base_ring of this point.

EXAMPLES:

sage: P.<x,y,z,w> = ProjectiveSpace(QQ,3)
sage: f = DynamicalSystem_projective([x^2, y^2, 4*w^2, 4*z^2], domain=P)
sage: Q = P.point([4, 4, 1, 1], False);
sage: Q.multiplier(f, 1)
[ 2  0 -8]
[ 0  2 -8]
[ 0  0 -2]
normalize_coordinates()

Removes the gcd from the coordinates of this point (including $$-1$$).

Warning

The gcd will depend on the base ring.

OUTPUT: None.

EXAMPLES:

sage: P = ProjectiveSpace(ZZ,2,'x')
sage: p = P([-5, -15, -20])
sage: p.normalize_coordinates(); p
(1 : 3 : 4)
sage: P = ProjectiveSpace(Zp(7),2,'x')
sage: p = P([-5, -15, -2])
sage: p.normalize_coordinates(); p
(5 + O(7^20) : 1 + 2*7 + O(7^20) : 2 + O(7^20))
sage: R.<t> = PolynomialRing(QQ)
sage: P = ProjectiveSpace(R,2,'x')
sage: p = P([3/5*t^3, 6*t, t])
sage: p.normalize_coordinates(); p
(3/5*t^2 : 6 : 1)
sage: P.<x,y> = ProjectiveSpace(Zmod(20),1)
sage: Q = P(3, 6)
sage: Q.normalize_coordinates()
sage: Q
(1 : 2)

Since the base ring is a polynomial ring over a field, only the gcd $$c$$ is removed.

sage: R.<c> = PolynomialRing(QQ)
sage: P = ProjectiveSpace(R,1)
sage: Q = P(2*c, 4*c)
sage: Q.normalize_coordinates();Q
(2 : 4)

A polynomial ring over a ring gives the more intuitive result.

sage: R.<c> = PolynomialRing(ZZ)
sage: P = ProjectiveSpace(R,1)
sage: Q = P(2*c, 4*c)
sage: Q.normalize_coordinates();Q
(1 : 2)
sage: R.<t> = PolynomialRing(QQ,1)
sage: S = R.quotient_ring(R.ideal(t^3))
sage: P.<x,y> = ProjectiveSpace(S,1)
sage: Q = P(t, t^2)
sage: Q.normalize_coordinates()
sage: Q
(1 : tbar)
nth_iterate(f, n, **kwds)

Return the n-th iterate of this point for the map f.

If normalize==True, then the coordinates are automatically normalized. If check==True, then the initialization checks are performed on the new point.

INPUT:

• f – a SchmemMorphism_polynomial with the points in its domain.
• n – a positive integer.

kwds:

• check – Boolean (optional - default: True).
• normalize – Boolean (optional Default: False).

OUTPUT:

• A point in the domain of f.`

EXAMPLES:

sage: P.<x,y> = ProjectiveSpace(ZZ, 1)
sage: f = DynamicalSystem_projective([x^2+y^2, 2*y^2], domain=P)
sage: P(1, 1).nth_iterate(f, 4)
doctest:warning
...
(32768 : 32768)
orbit(f, N, **kwds)

Returns the orbit of this point by the map f.

If N is an integer it returns $$[P,self(P),\ldots,self^N(P)]$$. If N is a list or tuple $$N=[m,k]$$ it returns $$[self^m(P),\ldots,self^k(P)$$]. Automatically normalize the points if normalize=True. Perform the checks on point initialization if check=True

INPUT:

• f – a SchemeMorphism_polynomial with this point in the domain of f.
• N – a non-negative integer or list or tuple of two non-negative integers.

kwds:

• check – boolean (optional - default: True).
• normalize – boolean (optional - default: False).

OUTPUT:

• a list of points in the domain of f.

EXAMPLES:

sage: P.<x,y,z> = ProjectiveSpace(ZZ,2)
sage: f = DynamicalSystem_projective([x^2+y^2, y^2-z^2, 2*z^2], domain=P)
sage: P(1, 2, 1).orbit(f, 3)
doctest:warning
...
[(1 : 2 : 1), (5 : 3 : 2), (34 : 5 : 8), (1181 : -39 : 128)]
scale_by(t)

Scale the coordinates of the point by t.

A TypeError occurs if the point is not in the base_ring of the codomain after scaling.

INPUT:

• t – a ring element.

OUTPUT: None.

EXAMPLES:

sage: R.<t> = PolynomialRing(QQ)
sage: P = ProjectiveSpace(R, 2, 'x')
sage: p = P([3/5*t^3, 6*t, t])
sage: p.scale_by(1/t); p
(3/5*t^2 : 6 : 1)
sage: R.<t> = PolynomialRing(QQ)
sage: S = R.quo(R.ideal(t^3))
sage: P.<x,y,z> = ProjectiveSpace(S, 2)
sage: Q = P(t, 1, 1)
sage: Q.scale_by(t);Q
(tbar^2 : tbar : tbar)
sage: P.<x,y,z> = ProjectiveSpace(ZZ,2)
sage: Q = P(2, 2, 2)
sage: Q.scale_by(1/2);Q
(1 : 1 : 1)